{
  lib,
  buildGoModule,
  fetchFromGitHub,
}:

buildGoModule rec {
  pname = "shardr";
  # Pinned to a commit: upstream has no tagged source releases, only
  # prebuilt "shardr-runner" bundles.
  version = "0-unstable-2026-10-02";

  src = fetchFromGitHub {
    owner = "Cyb3rDudu";
    repo = "shardr";
    rev = "fab7fa89bc8164181c5bcebd1f23a74825d11de1";
    hash = "sha256-bbNvTU3rSlKD7Wr+Q+WGKKtIVUq6uzmv93uZq0gzO2U=";
  };

  vendorHash = "sha256-wI7oVOFEKDK2hr7MmJ/QY9Mqwgk6t24cBe8HSM/zpVo=";

  subPackages = [
    "cmd/shardr"
    "cmd/shardhive"
  ];

  # Upstream tests assume a llama-server binary and a live shardhive socket.
  doCheck = false;

  passthru = {
    category = "AI Inference";
    updateScript = [
      "nix-update"
      "--flake"
      ".#shardr"
      "--version=branch=main"
    ];
  };

  meta = {
    description = "Decentralized LLM repository with sync-based distribution over a BitTorrent peer network";
    homepage = "https://github.com/Cyb3rDudu/shardr";
    changelog = "https://github.com/Cyb3rDudu/shardr/releases";
    license = lib.licenses.asl20;
    maintainers = [ ];
    mainProgram = "shardr";
  };
}