Files
millerson-overlay.nix/packages/strixite/package.nix
T
2026-11-12 23:55:09 +03:00

106 lines
2.9 KiB
Nix

{
lib,
stdenv,
fetchFromGitHub,
cmake,
ninja,
therockRocm,
}:
let
hostFlags = import ../../_lib/therock-host-flags.nix {
inherit lib stdenv;
};
programs = [
"strix_server"
"convert_qwen4exp"
"convert_ngram_table"
"transcode_ngram_table"
"inspect_strixw"
"check_stream_calls"
];
in
stdenv.mkDerivation (finalAttrs: {
pname = "strixite";
version = "0.7.0";
src = fetchFromGitHub {
owner = "shawnshekari";
repo = "strixite";
tag = "v${finalAttrs.version}";
hash = "sha256-zhyM4weEwMmjcTtxiJOi0PDatj4X8QAPSZKkLmqMAJo=";
};
nativeBuildInputs = [
cmake
ninja
];
cmakeFlags = [
"-DSTRIX_ROCM_ROOT=${therockRocm}"
"-DSTRIX_GPU_ARCH=gfx1151"
"-DSTRIX_HOST_ARCH=znver5"
"-DSTRIX_GCC_INSTALL_DIR=${stdenv.cc.cc}/lib/gcc/${stdenv.hostPlatform.config}/${stdenv.cc.cc.version}"
"-DCMAKE_C_COMPILER=${therockRocm}/lib/llvm/bin/clang"
"-DCMAKE_CXX_COMPILER=${therockRocm}/lib/llvm/bin/clang++"
];
env = {
CFLAGS = hostFlags;
CXXFLAGS = hostFlags;
ROCM_PATH = "${therockRocm}";
};
preConfigure = ''
export PATH=${therockRocm}/lib/llvm/bin:$PATH
export LD_LIBRARY_PATH=${therockRocm}/lib:${therockRocm}/lib/llvm/lib''${LD_LIBRARY_PATH:+:$LD_LIBRARY_PATH}
'';
ninjaFlags = programs;
installPhase = ''
runHook preInstall
install -Dt $out/bin ${lib.concatStringsSep " " programs}
install -Dm644 ../deploy/strix-server.conf $out/share/strixite/strix-server.conf
install -Dm644 ../LICENSE $out/share/licenses/strixite/LICENSE
install -Dm644 ../THIRD_PARTY.md $out/share/licenses/strixite/THIRD_PARTY.md
install -Dm644 ../third_party/cpp-httplib/LICENSE $out/share/licenses/strixite/cpp-httplib/LICENSE
install -Dm644 ../third_party/libwebp/COPYING $out/share/licenses/strixite/libwebp/COPYING
install -Dm644 ../third_party/libwebp/PATENTS $out/share/licenses/strixite/libwebp/PATENTS
runHook postInstall
'';
doInstallCheck = true;
installCheckPhase = ''
runHook preInstallCheck
$out/bin/strix_server --help > /dev/null
$out/bin/strix_server --print-config > /dev/null
runHook postInstallCheck
'';
passthru = {
rocm = therockRocm;
category = "AI Inference";
# Build in the Nix sandbox, then run explicitly on a host with GPU access.
tests.gpu = finalAttrs.finalPackage.overrideAttrs (old: {
pname = "strixite-gpu-smoke";
ninjaFlags = [ "first_kernel" ];
installPhase = ''
install -Dm755 tutorial/first_kernel $out/bin/first_kernel
'';
doInstallCheck = false;
passthru = { };
meta = old.meta // {
mainProgram = "first_kernel";
};
});
};
meta = {
description = "HIP inference engine and OpenAI-compatible server for Qwen3.8-Flash-Next on AMD Strix Halo";
homepage = "https://github.com/shawnshekari/strixite";
license = lib.licenses.agpl3Only;
platforms = [ "x86_64-linux" ];
mainProgram = "strix_server";
};
})