# Copyright 2021-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

DISTUTILS_USE_PEP517=setuptools
PYTHON_COMPAT=( python3_{11..13} )

EGIT_COMMIT=fcacc94b9f72d9b6b1f03779b0c6e07209ceb54b

inherit distutils-r1 optfeature

DESCRIPTION="Build Bespoke OS Images"
HOMEPAGE="https://github.com/systemd/mkosi"
SRC_URI="https://github.com/systemd/mkosi/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"

IUSE="qemu systemd kernel-install"

LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
	qemu? ( app-emulation/qemu )
	sys-apps/bubblewrap
	systemd? ( sys-apps/systemd )"
BDEPEND="virtual/pandoc"

S="${WORKDIR}/${PN}-${EGIT_COMMIT}"

distutils_enable_tests pytest

src_compile() {
	distutils-r1_src_compile

	./tools/make-man-page.sh || die
}

src_install() {
	distutils-r1_src_install

	doman mkosi/resources/man/*.1
	doman mkosi/resources/man/*.7

    if use kernel-install; then
      exeinto /usr/lib/kernel/install.d
      doexe kernel-install/50-mkosi.install
    fi
}

pkg_postinst() {
	optfeature "debian support" dev-util/debootstrap
}
