# Copyright 2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2

EAPI=8

inherit go-module

EGIT_COMMIT=a303c89133e4047f310ac79fc1a6b9b83a5049cf
DESCRIPTION="Fast and secure initramfs generator"
HOMEPAGE="https://github.com/anatol/booster"
SRC_URI="https://github.com/anatol/${PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
         https://git.millerson.name/alex/gentoo-artifacts/releases/download/${P}-vendor/${P}-vendor.tar.xz"

LICENSE="MIT"
SLOT="0"
KEYWORDS="~amd64"

S="${WORKDIR}/${PN}-${EGIT_COMMIT}"

IUSE="kernel-install installkernel"

DEPEND="kernel-install? (
	|| (
	    sys-apps/systemd-utils
	    sys-apps/systemd
	    )
	)
	installkernel? ( sys-kernel/installkernel )
	"
RDEPEND="${DEPEND}"

src_compile() {
	cd "${S}/generator" && ego build
	cd "${S}/init" && ego build
}

src_install() {
	insinto /etc
	newins "${FILESDIR}/${PN}.yaml" "${PN}.yaml"

	if use installkernel; then
		# Install the kernel preinst.d hook
		exeinto /usr/lib/kernel/preinst.d
		newexe "${FILESDIR}/installkernel-52-booster.install" 52-booster.install
	fi
	if use kernel-install; then
		exeinto /usr/lib/kernel/install.d
		doexe packaging/common/50-booster.install
	fi

	exeinto "/usr/lib/${PN}"
	doexe init/init

	newbin generator/generator "${PN}"

	default
}