media-gfx/imv: add 5.0.1

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

media-gfx/imv/Manifest

@@ -1,2 +1,3 @@
 DIST imv-4.5.0.tar.gz 82559 BLAKE2B 100174071049ee711a868832ea297cc7fd43450145db9e71a631afb97d7d77574f37501b749734f47b3f2699d159ed05e5159fd9060c6f0a5de18b92708d9e9c SHA512 5a192e1721b4752ba98de23e4a709904f43cce6954d1bc4a8feb5fb4921b46d497915fb7b2885cf87a65983fe2727c856d6c0c8b0cca2906e4b069e4a4f9c417
 DIST imv-5.0.0.tar.gz 71306 BLAKE2B bc65c1c0006a22dc09d01d914aa1eb32bdf6e54344053a94c9f1c56955d8f5056b57bacc180375aaa426db097335548692264b7f9fd47e9854196ec9e2e0deec SHA512 4c551ab5aba31d4bf41be13bb8d26df311fba2969c6ad36f706e76e45c854c8d47d16c6011fa54ebd369722c7ebb4ea797e4c86ef537ed2d2c87db4bbace6886
+DIST imv-5.0.1.tar.gz 72953 BLAKE2B 8fc7fd566b24decb4cc06e95223d4ec42fed62e1fdca879437f5e5319652479cc2e6e6ab3d804fb5848cbacd33bcc6e4f30076940f5a7b4ead5fd3dc44b03992 SHA512 9a53119b4bdb2c4b848ac5d7138f98948973bfa52ef3da111ca3c9eff5e11daf90529cd8c4898643bc7bde712b9c0e62fee9770a55f4e220abd4587ce651bba7

media-gfx/imv/imv-5.0.1.ebuild

@@ -0,0 +1,88 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Minimal image viewer designed for tiling window manager users"
+HOMEPAGE="https://sr.ht/~exec64/imv/"
+SRC_URI="https://git.sr.ht/~exec64/imv/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S=${WORKDIR}/${PN}-v${PV}
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
+IUSE="+X bmp gif heif icu +jpeg jpegxl +png svg test tiff wayland webp"
+REQUIRED_USE="|| ( X wayland )"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-libs/glib:2
+	dev-libs/inih
+	media-libs/libglvnd[X?]
+	x11-libs/cairo
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango
+	X? (
+		x11-libs/libX11
+		x11-libs/libxcb:=
+	)
+	bmp? ( media-libs/libnsbmp:= )
+	gif? ( >=media-libs/libnsgif-1:= )
+	heif? ( media-libs/libheif:= )
+	icu? ( dev-libs/icu:= )
+	!icu? ( >=dev-libs/libgrapheme-2:= )
+	jpeg? ( media-libs/libjpeg-turbo:= )
+	jpegxl? ( media-libs/libjxl:= )
+	png? ( media-libs/libpng:= )
+	svg? ( >=gnome-base/librsvg-2.44:2 )
+	tiff? ( media-libs/tiff:= )
+	wayland? ( dev-libs/wayland )
+	webp? ( media-libs/libwebp:= )
+	!sys-apps/renameutils
+"
+DEPEND="
+	${RDEPEND}
+	X? ( x11-base/xorg-proto )
+	test? ( dev-util/cmocka )
+	wayland? ( dev-libs/wayland-protocols )
+"
+BDEPEND="
+	app-text/asciidoc
+	test? ( || ( dev-util/xxd app-editors/vim-core ) )
+	wayland? ( dev-util/wayland-scanner )
+"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-5.0.0-nsgif-version.patch
+)
+
+src_prepare() {
+	default
+
+	# if wayland-only, don't automagic on libGL and force libOpenGL
+	if use !X; then
+		sed -i "/dependency('gl'/{s/'gl'/'opengl'/;s/false/true/}" meson.build || die
+	fi
+}
+
+src_configure() {
+	local emesonargs=(
+		$(meson_feature bmp libnsbmp)
+		$(meson_feature gif libnsgif)
+		$(meson_feature heif libheif)
+		$(meson_feature jpeg libjpeg)
+		$(meson_feature jpegxl libjxl)
+		$(meson_feature png libpng)
+		-Dqoi=disabled # not packaged
+		$(meson_feature svg librsvg)
+		$(meson_feature test)
+		$(meson_feature tiff libtiff)
+		-Dunicode=$(usex icu{,} grapheme)
+		$(meson_feature webp libwebp)
+		-Dwindows=$(usex X $(usex wayland all x11) wayland)
+	)
+
+	meson_src_configure
+}