media-plugins/frei0r-plugins: add 2.4.1

Closes: https://bugs.gentoo.org/965880
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

media-plugins/frei0r-plugins/Manifest

@@ -1 +1,2 @@
 DIST frei0r-plugins-2.3.3.tar.gz 921452 BLAKE2B dcf1d4eabd767428656802252ee5c7b51d23618dcbe3f7dab6f6268d28781fd994ac69276553910670e9a438557e7d200b16ce16a6df0d44469bbc1e7580823f SHA512 4f1b7b098563b38379821a81b19e2f9722512827e6ef986e5bac836e4406ce23f7cb486fd882646a372044555a897c3532c4fa733f2e5797613c3b65aff4b015
+DIST frei0r-plugins-2.4.1.tar.gz 935380 BLAKE2B d32325e7df06bf6d31c202c68c086e5b0820a86a42fa18e3034188e9c04bc1edb83899d61669dc35cd5cd5572a628bec6e674f1ca63832a097b2e8d038cbf35f SHA512 d31576c5d1a11947f0303291287fca7c9d258cddc07d4b2a83ce147e3007b71d36d44a94b635f357c8fae670ebb954cb0a2a06aa2f13e61aa2cf0279ff49e530

media-plugins/frei0r-plugins/frei0r-plugins-2.4.1.ebuild

@@ -0,0 +1,51 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DOCS_BUILDER="doxygen"
+DOCS_DIR="doc"
+inherit cmake-multilib docs
+
+DESCRIPTION="A minimalistic plugin API for video effects"
+HOMEPAGE="https://www.dyne.org/software/frei0r/"
+SRC_URI="https://github.com/dyne/frei0r/archive/refs/tags/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/frei0r-${PV}"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc +facedetect +scale0tilt"
+
+RDEPEND="x11-libs/cairo[${MULTILIB_USEDEP}]
+	facedetect? ( >=media-libs/opencv-2.3.0:=[contrib,contribdnn,features2d,${MULTILIB_USEDEP}] )
+	scale0tilt? ( >=media-libs/gavl-1.2.0[${MULTILIB_USEDEP}] )"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	virtual/pkgconfig
+	doc? ( app-text/doxygen[dot] )
+"
+
+DOCS=( AUTHORS.md README.md )
+
+src_prepare() {
+	cmake_src_prepare
+
+	# https://bugs.gentoo.org/418243
+	sed -i \
+		-e '/set.*CMAKE_C_FLAGS/s:"): ${CMAKE_C_FLAGS}&:' \
+		src/filter/*/CMakeLists.txt || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DWITHOUT_OPENCV=$(usex !facedetect)
+		-DWITHOUT_GAVL=$(usex !scale0tilt)
+	)
+	cmake-multilib_src_configure
+}
+
+src_compile() {
+	cmake-multilib_src_compile
+	use doc && docs_compile
+}