diff --git a/dev-python/fonttools/Manifest b/dev-python/fonttools/Manifest
index cc91401c698a..b386de861b09 100644
--- a/dev-python/fonttools/Manifest
+++ b/dev-python/fonttools/Manifest
@@ -1 +1,2 @@
 DIST fonttools-4.60.1.gh.tar.gz 3997441 BLAKE2B 44d5e9e2eacc70b09782ee82c654c6dabdcfce6d1d32eb3e9c03bb466d6056b885cc50f615d9ad5909a7c201f0b461ea89c77c468da02e7879bb0e876e3d149e SHA512 50e887f7cfa3a35ba5ca606fe0ce4766185272804bbd05e880cc47b0b73b4af865d902e5a34391bca1fed45275bd1b7922c0bb2b1c6685b9a2aa7026ae70d104
+DIST fonttools-4.61.0.gh.tar.gz 3997800 BLAKE2B 8c7dd9c2d7027252e6ddc6f71dbdd8f96f1c9ebfd193a27a1f717c77bb2118259ef1ae78a5a5219e6a6c9c189e094c74a6267031a4f69b1d7ebeaefe43f73678 SHA512 4c5de3f63fb721817e5225cf928a4dde18c326cc495997452aba9fba057ddf3ddff6410f7ac178ba8fa17d78c11235c02d5898f9f9736cc9a421e20f49459c56
diff --git a/dev-python/fonttools/fonttools-4.61.0.ebuild b/dev-python/fonttools/fonttools-4.61.0.ebuild
new file mode 100644
index 000000000000..233efa804b3a
--- /dev/null
+++ b/dev-python/fonttools/fonttools-4.61.0.ebuild
@@ -0,0 +1,69 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYTHON_COMPAT=( pypy3_11 python3_{11..14} )
+PYTHON_REQ_USE="xml(+)"
+
+inherit distutils-r1 virtualx
+
+DESCRIPTION="Library for manipulating TrueType, OpenType, AFM and Type1 fonts"
+HOMEPAGE="
+	https://github.com/fonttools/fonttools/
+	https://pypi.org/project/fonttools/
+"
+SRC_URI="
+	https://github.com/fonttools/fonttools/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+IUSE="+native-extensions"
+
+BDEPEND="
+	native-extensions? (
+		$(python_gen_cond_dep '
+			dev-python/cython[${PYTHON_USEDEP}]
+		' 'python*')
+	)
+	test? (
+		dev-python/brotlicffi[${PYTHON_USEDEP}]
+		$(python_gen_cond_dep '
+			>=dev-python/fs-2.4.9[${PYTHON_USEDEP}]
+		' 3.{11..13})
+		dev-python/munkres[${PYTHON_USEDEP}]
+		app-arch/zopfli
+	)
+"
+
+EPYTEST_PLUGINS=( pytest-rerunfailures )
+EPYTEST_RERUNS=5
+EPYTEST_XDIST=1
+distutils_enable_tests pytest
+
+python_compile() {
+	local -x FONTTOOLS_WITH_CYTHON=$(usex native-extensions)
+	[[ ${EPYTHON} == pypy3 ]] && FONTTOOLS_WITH_CYTHON=0
+	distutils-r1_python_compile
+}
+
+src_test() {
+	# virtualx used when matplotlib is installed causing plot module tests to run
+	virtx distutils-r1_src_test
+}
+
+python_test() {
+	local EPYTEST_DESELECT=(
+		# flaky test
+		Tests/ttLib/woff2_test.py::WOFF2ReaderTest::test_get_normal_tables
+	)
+
+	# nonfatal for virtx
+	nonfatal epytest Tests fontTools ||
+		die -n "Tests failed with ${EPYTHON}"
+}