media-plugins/qmmp-plugin-pack: add 2.3.0

add three plugins :
video w/ mplayer (move from qmmp)
video w/ mpv (experimental)
mms support (move from qmmp)

Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Part-of: https://github.com/gentoo/gentoo/pull/44174
Closes: https://github.com/gentoo/gentoo/pull/44174
Signed-off-by: Sam James <sam@gentoo.org>

media-plugins/qmmp-plugin-pack/Manifest

@@ -1 +1,2 @@
 DIST qmmp-plugin-pack-2.2.2.tar.bz2 248813 BLAKE2B a1a1263b7a1626639864c621ce21f426c2f42b9f1cc463997f712762d0cf7a13388325111142e62341d55a5f5608ab788b8973e56dae3cd88a9fd39434370a25 SHA512 56b54e4377f8580964ad7ce08314e415e33a53d5d01b7cd56912c8821664511acf040b5d1e3835ea53d709103eb737bda890019cf0070bb8a95e0b203d9f4ec1
+DIST qmmp-plugin-pack-2.3.0.tar.bz2 263387 BLAKE2B 3c6623aaf0e27dab485e517bebf557033083a30044fb13c3e37a524c6a407775304dd9f9a91107842f445f50dc59f88fc0a9b73e62fbcb6945da3ce880c534ba SHA512 1ae3762bde61628482a3b1fb7d77ba25043ee462d49a879b91d205329b4553d70d917e8b45249e1dd356f9335352c12b3cb1cbb62e84743be987c2c3dcceca56

media-plugins/qmmp-plugin-pack/metadata.xml

@@ -5,4 +5,7 @@
 		<email>sound@gentoo.org</email>
 		<name>Gentoo Sound project</name>
 	</maintainer>
+	<use>
+		<flag name="mpv">Enable video support via <pkg>media-video/mpv</pkg>(experimental)</flag>
+	</use>
 </pkgmetadata>

media-plugins/qmmp-plugin-pack/qmmp-plugin-pack-2.3.0.ebuild

@@ -0,0 +1,53 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake optfeature
+
+DESCRIPTION="Set of extra plugins for Qmmp"
+HOMEPAGE="https://qmmp.ylsoftware.com/"
+SRC_URI="https://qmmp.ylsoftware.com/files/${PN}/$(ver_cut 1-2)/${P}.tar.bz2"
+
+LICENSE="GPL-2"
+SLOT="0"
+KEYWORDS="~amd64 ~x86"
+IUSE="ffmpeg +libsamplerate mms modplug mplayer mpv"
+
+RDEPEND="
+	dev-qt/qtbase:6[gui,network,widgets]
+	media-libs/taglib:=
+	=media-sound/qmmp-$(ver_cut 1-2)*
+	ffmpeg? ( media-video/ffmpeg:= )
+	libsamplerate? ( media-libs/libsamplerate )
+	mms? ( media-libs/libmms )
+	modplug? ( media-libs/libmodplug )
+	mplayer? ( media-video/mplayer )
+	mpv? (
+		media-video/ffmpeg:=
+		media-video/mpv:=[libmpv]
+	)
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	dev-qt/qttools:6[linguist]
+	virtual/pkgconfig
+"
+
+src_configure() {
+	local mycmakeargs=(
+		# enabled by default as taglib is already required by qmmp
+		-DUSE_FFAP=ON
+		-DUSE_FFVIDEO=$(usex ffmpeg)
+		-DUSE_MMS=$(usex mms)
+		-DUSE_MODPLUG=$(usex modplug)
+		-DUSE_MPLAYER=$(usex mplayer)
+		-DUSE_MPV=$(usex mpv)
+		-DUSE_SRC=$(usex libsamplerate)
+	)
+	cmake_src_configure
+}
+
+pkg_postinst() {
+	optfeature "audio playback from YouTube" net-misc/yt-dlp
+}