millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

app-misc/liquidctl: add 1.15.0

Browse Source 
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44562
Closes: https://github.com/gentoo/gentoo/pull/44562
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Alfred Wingate 2025-11-10 04:56:24 +02:00 committed by Sam James
parent 3df5e94f6a
commit 841c866545
No known key found for this signature in database
GPG Key ID: 738409F520DF9190
2 changed files with 56 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
app-misc/liquidctl/Manifest
View File

@ -1 +1,2 @@
DIST liquidctl-1.14.0.tar.gz 1876711 BLAKE2B d151ca7c2d59e117515772041e34f34e28999845a6a9e12c3a940c8e2431d5d38b809c1e8af65c6447c548e6051c4808bebb10b4132d444ea1cb7cf5ca3c90a7 SHA512 a27fd0ee1a9a4b08298ba0ddb862c0adedf1b2be64d8fa49a6dcb8a32aaffb70c9de6e324efe2626d50e070d33cd54985e581f25de254118f218f46716d0e938
DIST liquidctl-1.15.0.tar.gz 1877640 BLAKE2B 0e4204149bf6448908629e49d7b5af6db385a564961c146c32f765baf8df30a896d00682d0cd76ff010ef9617225cff811f6d272b5d8498f502ae2413ba4e5f5 SHA512 29c65c8aabc137b05c72b612abefee413af18984aff0682d0e066dc619f933dbac34cbac6f2d68302bdea706ea43d58ca6c5c30fb9ecfb2c8aad0c80d9d167db

55
app-misc/liquidctl/liquidctl-1.15.0.ebuild Normal file
View File

@ -0,0 +1,55 @@
# Copyright 2022-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
PYTHON_COMPAT=( python3_{11..14} )
DISTUTILS_USE_PEP517=setuptools
inherit distutils-r1 udev xdg-utils
DESCRIPTION="Cross-platform tool and drivers for liquid coolers and other devices"
HOMEPAGE="https://github.com/liquidctl/liquidctl"
SRC_URI="https://github.com/liquidctl/liquidctl/releases/download/v${PV}/${P}.tar.gz"
LICENSE="GPL-3+"
SLOT="0"
KEYWORDS="~amd64"
RDEPEND="
dev-python/colorlog[${PYTHON_USEDEP}]
~dev-python/crcmod-1.7[${PYTHON_USEDEP}]
dev-python/docopt[${PYTHON_USEDEP}]
dev-python/hidapi[${PYTHON_USEDEP}]
dev-python/pillow[${PYTHON_USEDEP}]
dev-python/pyusb[${PYTHON_USEDEP}]
sys-apps/i2c-tools[${PYTHON_USEDEP},python]
"
BDEPEND="
dev-python/setuptools-scm[${PYTHON_USEDEP}]
"
EPYTEST_PLUGINS=()
distutils_enable_tests pytest
src_test() {
# Clear xdg env, otherwise it attempts to write to /var/run and fails
xdg_environment_reset
distutils-r1_src_test
}
python_install_all() {
distutils-r1_python_install_all
dodoc docs/*.md
dodoc -r docs/linux/
udev_dorules extra/linux/71-liquidctl.rules
}
pkg_postinst() {
udev_reload
}
pkg_postrm() {
udev_reload
}