millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-09 00:07:57 +03:00
Code Issues Packages Projects Releases Wiki Activity

kde-apps/gwenview: 25.08.3 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner 2025-11-06 16:33:05 +01:00
parent feaf82e4a8
commit 9cb488a245
No known key found for this signature in database
GPG Key ID: AE591BBC73E4DD5E
2 changed files with 112 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/gwenview/Manifest
View File

@ -1 +1,2 @@
DIST gwenview-25.08.2.tar.xz 6533740 BLAKE2B 6f71731b48557d1d2968c0d72f24b64d3abdb184e2365f009736f14c2a31af116971d78942a8a4f9322295b8a9e1d02354b2026552f6d50706970c4dcdbe105f SHA512 d0d2438de57e24337f4165b070199c2276bd0e7131b8f0f35943e43aa85e493b2fb5240678513c6656f38189a0bb3c5493e613b18c696f8341651ee815f79007
DIST gwenview-25.08.3.tar.xz 6534116 BLAKE2B 7ee394c7ff710a21c6cebf723634bb88c2bb30a60cc19a92e5a3df4d0d65f8dc59b8bef4d50aaddfd9d48842edb2f8978d4cff7ab50aa918460a1c323e6e9b4a SHA512 bc6f316dd13ed06682cf96af80182ec4d3d38f50d6ce75ea50cc000f3cddbe40e0000dcfca3ebd3efedbd0768ee1c5ce7c40309c6a6f69ff23c1d6defaf24ff9

111
kde-apps/gwenview/gwenview-25.08.3.ebuild Normal file
View File

@ -0,0 +1,111 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=6.16.0
QTMIN=6.9.1
inherit ecm gear.kde.org optfeature xdg
DESCRIPTION="Image viewer by KDE"
HOMEPAGE="https://apps.kde.org/gwenview/ https://userbase.kde.org/Gwenview"
LICENSE="GPL-2+ handbook? ( FDL-1.2 )"
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="activities fits +mpris raw semantic-desktop share X"
# requires running environment
RESTRICT="test"
# slot op: includes qpa/qplatformnativeinterface.h, qtx11extras_p.h
COMMON_DEPEND="
dev-libs/wayland
>=dev-qt/qtbase-${QTMIN}:6=[gui,opengl,wayland,widgets]
>=dev-qt/qtmultimedia-${QTMIN}:6
>=dev-qt/qtsvg-${QTMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6
>=kde-frameworks/kitemmodels-${KFMIN}:6
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
media-gfx/exiv2:=
>=media-libs/kcolorpicker-0.3.1
>=media-libs/kimageannotator-0.7.1
media-libs/lcms:2
media-libs/libjpeg-turbo:=
media-libs/libpng:0=
media-libs/tiff:=
activities? ( kde-plasma/plasma-activities:6= )
fits? ( sci-libs/cfitsio )
mpris? ( >=dev-qt/qtbase-${QTMIN}:6[dbus] )
raw? ( >=kde-apps/libkdcraw-${PVCUT}:6 )
semantic-desktop? (
>=kde-frameworks/baloo-${KFMIN}:6
>=kde-frameworks/kfilemetadata-${KFMIN}:6
)
share? ( >=kde-frameworks/purpose-${KFMIN}:6 )
X? (
>=dev-qt/qtbase-${QTMIN}:6=[X]
x11-libs/libX11
)
"
DEPEND="${COMMON_DEPEND}
dev-libs/wayland-protocols
>=dev-qt/qtbase-${QTMIN}:6[concurrent]
>=kde-frameworks/kwindowsystem-${KFMIN}:6
"
RDEPEND="${COMMON_DEPEND}
>=dev-qt/qtimageformats-${QTMIN}:6
>=kde-apps/thumbnailers-${PVCUT}:6
>=kde-frameworks/kimageformats-${KFMIN}:6
"
RDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
BDEPEND="
>=dev-qt/qtbase-${QTMIN}:6[wayland]
dev-util/wayland-scanner
"
BDEPEND+=" || ( >=dev-qt/qtbase-6.10:6[wayland] <dev-qt/qtwayland-6.10:6 )"
src_prepare() {
ecm_src_prepare
if ! use mpris; then
# FIXME: upstream a better solution
sed -e "/set(HAVE_QTDBUS/s/\${Qt6DBus_FOUND}/0/" -i CMakeLists.txt || die
fi
}
src_configure() {
local mycmakeargs=(
$(cmake_use_find_package activities PlasmaActivities)
$(cmake_use_find_package fits CFitsio)
$(cmake_use_find_package raw KDcrawQt6)
-DGWENVIEW_SEMANTICINFO_BACKEND=$(usex semantic-desktop Baloo None)
$(cmake_use_find_package share KF6Purpose)
-DWITHOUT_X11=$(usex !X)
)
ecm_src_configure
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "SVG support" "kde-apps/svgpart:${SLOT}"
fi
xdg_pkg_postinst
}