millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-09 00:07:57 +03:00
Code Issues Packages Projects Releases Wiki Activity

kde-apps/dolphin: 25.08.3 version bump

Browse Source 
Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>
This commit is contained in:
Andreas Sturmlechner 2025-11-06 16:24:12 +01:00
parent 47cff0eb7f
commit a2679a946a
No known key found for this signature in database
GPG Key ID: AE591BBC73E4DD5E
2 changed files with 93 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
kde-apps/dolphin/Manifest
View File

@ -1 +1,2 @@
DIST dolphin-25.08.2.tar.xz 5816516 BLAKE2B acec6ffc741c686c9593b1dc48c3302eac47a3724fc7eb60b404427ac6cdb890263e70267a5768d2219c7220003d2310a856558923c9af7f38c5380f2c42a4cf SHA512 7df7e61bf85914d32b77145548cf79238b59a4e6ef4c64ab81afb2583b5f6245156b06941b11211cc73e6c4dd0a543503bbde2fda3fa216cbc6b4977c8036c72
DIST dolphin-25.08.3.tar.xz 5819800 BLAKE2B ae13c0a254e0dace4eb866ba9926f1df0bfe467ffdc8977068ba3487ca2f6bd12a3d2e3d12c338bbd36821f0413b963464ec1a93db51cf82d8716045d759619a SHA512 67e4edf940d066ef4989553527d9e936ea1208d0b70ff66d9899ee5f5f074466170b1dd6cbfd9d1d06c9288d94e47a43d31fc5017883859cb5242be31be14493

92
kde-apps/dolphin/dolphin-25.08.3.ebuild Normal file
View File

@ -0,0 +1,92 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
ECM_HANDBOOK="optional"
ECM_TEST="true"
PVCUT=$(ver_cut 1-3)
KFMIN=6.16.0
QTMIN=6.9.1
inherit ecm gear.kde.org optfeature xdg
DESCRIPTION="Plasma filemanager focusing on usability"
HOMEPAGE="https://apps.kde.org/dolphin/ https://userbase.kde.org/Dolphin"
LICENSE="GPL-2" # TODO: CHECK
SLOT="6"
KEYWORDS="~amd64 ~arm64 ~loong ~ppc64 ~riscv ~x86"
IUSE="semantic-desktop telemetry"
# slot op: Uses Qt::GuiPrivate for qtx11extras_p.h
DEPEND="
>=dev-qt/qtbase-${QTMIN}:6=[concurrent,dbus,gui,widgets,X,xml]
>=dev-qt/qtmultimedia-${QTMIN}:6
>=kde-frameworks/kbookmarks-${KFMIN}:6
>=kde-frameworks/kcmutils-${KFMIN}:6
>=kde-frameworks/kcodecs-${KFMIN}:6
>=kde-frameworks/kcolorscheme-${KFMIN}:6
>=kde-frameworks/kcompletion-${KFMIN}:6
>=kde-frameworks/kconfig-${KFMIN}:6
>=kde-frameworks/kconfigwidgets-${KFMIN}:6
>=kde-frameworks/kcoreaddons-${KFMIN}:6
>=kde-frameworks/kcrash-${KFMIN}:6
>=kde-frameworks/kdbusaddons-${KFMIN}:6
>=kde-frameworks/kfilemetadata-${KFMIN}:6
>=kde-frameworks/kguiaddons-${KFMIN}:6
>=kde-frameworks/ki18n-${KFMIN}:6
>=kde-frameworks/kiconthemes-${KFMIN}:6
>=kde-frameworks/kio-${KFMIN}:6=
>=kde-frameworks/kitemviews-${KFMIN}:6
>=kde-frameworks/kjobwidgets-${KFMIN}:6
>=kde-frameworks/knewstuff-${KFMIN}:6
>=kde-frameworks/knotifications-${KFMIN}:6
>=kde-frameworks/kparts-${KFMIN}:6
>=kde-frameworks/kservice-${KFMIN}:6
>=kde-frameworks/ktextwidgets-${KFMIN}:6
>=kde-frameworks/kwidgetsaddons-${KFMIN}:6
>=kde-frameworks/kwindowsystem-${KFMIN}:6
>=kde-frameworks/kxmlgui-${KFMIN}:6
>=kde-frameworks/solid-${KFMIN}:6
semantic-desktop? (
>=kde-apps/baloo-widgets-${PVCUT}:6
>=kde-frameworks/baloo-${KFMIN}:6
)
telemetry? ( >=kde-frameworks/kuserfeedback-${KFMIN}:6 )
"
RDEPEND="${DEPEND}
>=kde-apps/kio-extras-${PVCUT}:6
>=kde-apps/thumbnailers-${PVCUT}:6
"
src_configure() {
local mycmakeargs=(
-DCMAKE_DISABLE_FIND_PACKAGE_PackageKitQt6=ON
$(cmake_use_find_package semantic-desktop KF6Baloo)
$(cmake_use_find_package semantic-desktop KF6BalooWidgets)
$(cmake_use_find_package telemetry KF6UserFeedback)
)
use test && mycmakeargs+=(
-DCMAKE_DISABLE_FIND_PACKAGE_SeleniumWebDriverATSPI=ON # not packaged
)
ecm_src_configure
}
src_test() {
local myctestargs=(
# servicemenuinstaller requires ruby, no thanks
# dolphinmainwindowtest, kitemlistcontrollertest, kfileitemlistviewtest, kfileitemmodeltest hang forever
# placesitemmodeltest requires DBus
-E "(servicemenuinstaller|dolphinmainwindowtest|kfileitemlistviewtest|kfileitemmodeltest|kitemlistcontrollertest|placesitemmodeltest)"
)
ecm_src_test
}
pkg_postinst() {
if [[ -z "${REPLACING_VERSIONS}" ]]; then
optfeature "compress/extract and other actions" "kde-apps/ark:${SLOT}"
optfeature "crypto actions" "kde-apps/kleopatra:${SLOT}"
optfeature "'Share' context menu actions" "kde-frameworks/purpose:${SLOT}"
fi
xdg_pkg_postinst
}