net-libs/libktorrent: 25.08.3 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

net-libs/libktorrent/Manifest

@@ -1 +1,2 @@
 DIST libktorrent-25.08.2.tar.xz 607096 BLAKE2B 76728fd2ecb002c12629a0d2f1a0d8e7763811711c42f8e5aaa2af4598d60f6974945418df8a9eae5c940f98039ed8548ae9a5c6484f83ae30b8c17d7f017e04 SHA512 9d9bbbc8310d67fe1cf3f619c4c21a575664265cadbd525d90f63733fcb58e3b24cc270c2f13396acf806c7c721ce4713e3132f5e0852c4b5cb4288daef711da
+DIST libktorrent-25.08.3.tar.xz 607156 BLAKE2B a1786b7fa68f990cfd5f5cbc9c0ddf54815c319052ed93c13f0a43ea8e31f4e3466e521567e0a91bb7a401cff24c1c16fc0c607c73580dc8dca8687552d8c161 SHA512 18cdac7194dcaab58568d844c48bd5ca21983bb99784f14f82d15aa620c24bfde27ef298e519cc5f5d2472fcba65288dc5458027faecf754a92b83e637404ae4

net-libs/libktorrent/libktorrent-25.08.3.ebuild

@@ -0,0 +1,65 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+ECM_TEST="forceoptional"
+KDE_ORG_CATEGORY="network"
+KFMIN=6.16.0
+QTMIN=6.9.1
+inherit ecm gear.kde.org
+
+DESCRIPTION="BitTorrent library based on KDE Frameworks"
+HOMEPAGE="https://apps.kde.org/ktorrent/ https://userbase.kde.org/KTorrent"
+
+LICENSE="GPL-2+"
+SLOT="6"
+KEYWORDS="~amd64 ~arm64 ~ppc64 ~riscv ~x86"
+IUSE="xfs"
+
+COMMON_DEPEND="
+	>=dev-libs/gmp-6.0.0a:0=
+	>=dev-libs/openssl-3:0=
+	>=dev-qt/qtbase-${QTMIN}:6[network,xml]
+	>=kde-frameworks/karchive-${KFMIN}:6
+	>=kde-frameworks/kconfig-${KFMIN}:6
+	>=kde-frameworks/kcoreaddons-${KFMIN}:6
+	>=kde-frameworks/kcrash-${KFMIN}:6
+	>=kde-frameworks/ki18n-${KFMIN}:6
+	>=kde-frameworks/kio-${KFMIN}:6
+	>=kde-frameworks/solid-${KFMIN}:6
+	xfs? ( sys-fs/xfsprogs )
+"
+DEPEND="${COMMON_DEPEND}
+	>=dev-libs/boost-1.71
+"
+RDEPEND="${COMMON_DEPEND}
+	!dev-libs/botan[gmp(-)]
+"
+BDEPEND="sys-devel/gettext"
+
+src_prepare() {
+	ecm_src_prepare
+
+	# Gentoo workaround because gmp.h in MULTILIB_WRAPPED_HEADERS is breaking this
+	sed -i -e "/^find_package/ s/\"\${LibGMP_MIN_VERSION}\" //" \
+		CMakeLists.txt || die
+	sed -i -e "/^find_dependency/ s/ \"@LibGMP_MIN_VERSION@\"//" \
+		KTorrent6Config.cmake.in || die
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DUSE_CRYPTO_BACKEND=OpenSSL
+		-DWITH_XFS=$(usex xfs)
+	)
+	ecm_src_configure
+}
+
+src_test() {
+	# failing network tests
+	local myctestargs=(
+		-E "(fin|packetloss|send|superseedtest|transmit|utppolltest)"
+	)
+	ecm_src_test
+}