diff --git a/dev-python/mkdocs-material/Manifest b/dev-python/mkdocs-material/Manifest
index 42d272decc56..84157d59d332 100644
--- a/dev-python/mkdocs-material/Manifest
+++ b/dev-python/mkdocs-material/Manifest
@@ -1,2 +1,3 @@
 DIST mkdocs-material-9.6.20.gh.tar.gz 14933529 BLAKE2B bb4bd67e3d29d3528406bfd21f34614b8aa11b442714711c96589afbb3f758a90eaefa7a4784c0ab4d5c6befbb4e1d1625c702237242b488a0c7fc63be367c44 SHA512 2336ede01937aff3bc47117deb96423d2c115430a77343f3de3668898d47240e6d06286b76d9342ac31eac5369cdc9b7f4bf80cbf3a5b49c9dec76c6a547aca3
 DIST mkdocs-material-9.6.21.gh.tar.gz 14941581 BLAKE2B cfb1182279ec2a5ac7fbb6970b9f6724893f17b529d2857d0cf8dfa4d0527c3527a49235cb29a636dc5110ca57279206904f94c36012d14156f4b055f0a6857c SHA512 5cc2f0da266627b901788ecccd759bff535bfed83086fcfe73da92dbc0789c1c77286ae37fcfb07385bc7fdebbd1770e709cf1ee2746e11f36325add14fa97ed
+DIST mkdocs-material-9.6.22.gh.tar.gz 14941613 BLAKE2B bc7a76f70d3813dc3a7881703335fa94ff19ca24aca1a69e6b5800aefc6f62d26b4c912f652dfdf045ec11e9623a743c5a2058118d987a9fdf693b337428be09 SHA512 e516fb0400edbc1f59befb43d81245baa97d6e95b3538e19e53845816dc4b13833907df910a10dbab93fcf8df600bccd4fff099cc01f762767882d8d5655ae47
diff --git a/dev-python/mkdocs-material/mkdocs-material-9.6.22.ebuild b/dev-python/mkdocs-material/mkdocs-material-9.6.22.ebuild
new file mode 100644
index 000000000000..4fec7b2ae395
--- /dev/null
+++ b/dev-python/mkdocs-material/mkdocs-material-9.6.22.ebuild
@@ -0,0 +1,73 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
+
+DOCS_BUILDER="mkdocs"
+DOCS_DEPEND="
+	dev-python/mkdocs-material-extensions
+	dev-python/mkdocs-minify-plugin
+	dev-python/mkdocs-redirects
+"
+
+inherit distutils-r1 docs
+
+DESCRIPTION="A Material Design theme for MkDocs"
+HOMEPAGE="
+	https://github.com/squidfunk/mkdocs-material/
+	https://pypi.org/project/mkdocs-material/
+"
+SRC_URI="
+	https://github.com/squidfunk/${PN}/archive/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="MIT"
+# bundled icons
+LICENSE+=" Apache-2.0 CC0-1.0 CC-BY-4.0 MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="social"
+
+RDEPEND="
+	>=dev-python/babel-2.10.3[${PYTHON_USEDEP}]
+	>=dev-python/colorama-0.4[${PYTHON_USEDEP}]
+	>=dev-python/jinja2-3.0.2[${PYTHON_USEDEP}]
+	>=dev-python/lxml-4.6[${PYTHON_USEDEP}]
+	>=dev-python/markdown-3.2[${PYTHON_USEDEP}]
+	>=dev-python/mkdocs-1.5.3[${PYTHON_USEDEP}]
+	>=dev-python/paginate-0.5.6[${PYTHON_USEDEP}]
+	>=dev-python/pygments-2.16[${PYTHON_USEDEP}]
+	>=dev-python/pymdown-extensions-10.2[${PYTHON_USEDEP}]
+	>=dev-python/readtime-2.0[${PYTHON_USEDEP}]
+	$(python_gen_cond_dep '
+		>=dev-python/regex-2022.4.24[${PYTHON_USEDEP}]
+	' 'python*')
+	>=dev-python/requests-2.26[${PYTHON_USEDEP}]
+	social? (
+		>=dev-python/pillow-10.2[${PYTHON_USEDEP}]
+		>=media-gfx/cairosvg-2.5[${PYTHON_USEDEP}]
+	)
+"
+BDEPEND="
+	>=dev-python/trove-classifiers-2023.10.18[${PYTHON_USEDEP}]
+"
+# mkdocs-material-extensions depends on mkdocs-material creating a circular dep
+PDEPEND="
+	>=dev-python/mkdocs-material-extensions-1.2[${PYTHON_USEDEP}]
+"
+
+PATCHES=(
+	# simplify pyproject to remove extra deps for metadata
+	"${FILESDIR}/${PN}-8.5.7-simplify-build.patch"
+	# import backrefs only when used (i.e. never)
+	"${FILESDIR}/${PN}-9.6.7-backrefs.patch"
+)
+
+src_prepare() {
+	distutils-r1_src_prepare
+	echo "__version__ = '${PV}'" > gentoo_version.py || die
+}