millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

media-libs/libpng: add 1.6.52

Browse Source 
Bug: https://bugs.gentoo.org/967052
Signed-off-by: Sam James <sam@gentoo.org>
This commit is contained in:
Sam James 2025-12-04 01:07:43 +00:00
parent a409455d95
commit c29f3c940d
No known key found for this signature in database
GPG Key ID: 738409F520DF9190
2 changed files with 79 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
media-libs/libpng/Manifest
View File

@ -4,3 +4,4 @@ DIST libpng-1.6.49-libpng-apng-apng.patch.gz 10676 BLAKE2B a726acae0da7905c5f1c5
DIST libpng-1.6.50.tar.xz 1060992 BLAKE2B 2191536b4448d3a058b9dbb31f3d780959c9daf7b104550cc89e8ae984a3c9f01b86bf6c6708983989b4bfbe7232e3716b8a3b8cd3313a12c31e0623b6241d11 SHA512 05adc94ef532bbddaae46e087088a23236e6528fd3fc705c8edfb5ff293983b790d4361d6b20c20df73632a9fbe55d2f394296385cd8efd646f58393ff21257d
DIST libpng-1.6.51-libpng-apng-apng.patch.gz 10686 BLAKE2B 71cab27854831c640de6d2d3dc3c1e38cb104ee5fe7012cce5662c4362b2289b3e3a0f623eb3335c025efa12ce81dd3da698f5cc6862a20e7439445bb4153a51 SHA512 746f74058d51d9f042479f296cdbd77b40ddb4cf1f8a94f6e1ca08b453f42bbda780689975f7607d54b8a0cd86f72e7a2804259b3afa1ddc1342e987bed5814d
DIST libpng-1.6.51.tar.xz 1060772 BLAKE2B 2d1ee36f9796e90a533abf26597df82c39cfab42f8d4044d35e0fdbab65612b9fc0234780677e2ea758450db9815b9d30870e8024bcebc0170c87361b7c4cc0a SHA512 c723406f050f99783b2576e7e2c84774630a7f46bb8ea82bf4932f82bbb4899f47cb1b19ff9020245a474a0b2fee82c55ac1c58db43e3888ad5cc3a1767e7433
DIST libpng-1.6.52.tar.xz 1063580 BLAKE2B 47732b5e1a9d35e6aa2b7d1b967842588410154ada06af9d9c3fafaaf2440f1b70a1c9d4c0329b29b401f182ac4cc1fe88dc312e8a17e82aafd4ca954910221b SHA512 2bb1318f36712fc007613373a44a3276b4ed129b51b908464d9577ea9704d3caa469ec5bc7ebfb8b1de57ba3998c0b3375cd105054011ec54c21e9f208ec3c8b

78
media-libs/libpng/libpng-1.6.52.ebuild Normal file
View File

@ -0,0 +1,78 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit dot-a libtool multilib-minimal
APNG_REPO=libpng-apng # sometimes libpng-apng is more up to date
APNG_VERSION="1.6.51"
DESCRIPTION="Portable Network Graphics library"
HOMEPAGE="https://www.libpng.org/"
SRC_URI="
https://downloads.sourceforge.net/${PN}/${P}.tar.xz
apng? (
https://downloads.sourceforge.net/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PV}/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
https://downloads.sourceforge.net/${APNG_REPO}/${PN}$(ver_rs 1-2 '' $(ver_cut 1-2 ${APNG_VERSION}))/${PN}-${APNG_VERSION}-apng.patch.gz -> ${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch.gz
)
"
LICENSE="libpng2"
SLOT="0/16"
KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~arm64-macos ~ppc-macos ~x64-macos ~x64-solaris"
IUSE="apng cpu_flags_x86_sse static-libs test"
RESTRICT="!test? ( test )"
RDEPEND=">=virtual/zlib-1.2.8-r1:=[${MULTILIB_USEDEP}]"
DEPEND="
${RDEPEND}
riscv? ( sys-kernel/linux-headers )
"
DOCS=( ANNOUNCE CHANGES libpng-manual.txt README TODO )
src_prepare() {
default
if use apng; then
case ${APNG_REPO} in
apng)
eapply -p0 "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
;;
libpng-apng)
eapply "${WORKDIR}"/${PN}-${APNG_VERSION}-${APNG_REPO}-apng.patch
;;
*)
die "Unknown APNG_REPO!"
;;
esac
# Don't execute symbols check with apng patch, bug #378111
sed -i -e '/^check/s:scripts/symbols.chk::' Makefile.in || die
fi
elibtoolize
}
src_configure() {
lto-guarantee-fat
multilib-minimal_src_configure
}
multilib_src_configure() {
local myeconfargs=(
$(multilib_native_enable tools)
$(use_enable test tests)
$(use_enable cpu_flags_x86_sse intel-sse)
$(use_enable static-libs static)
)
ECONF_SOURCE="${S}" econf "${myeconfargs[@]}"
}
multilib_src_install_all() {
default
strip-lto-bytecode
find "${ED}" \( -type f -o -type l \) -name '*.la' -delete || die
}