dev-util/vulkan-utility-libraries: add 1.4.328.0

Signed-off-by: Nick Sarnie <sarnex@gentoo.org>

dev-util/vulkan-utility-libraries/Manifest

@@ -1 +1,2 @@
 DIST vulkan-utility-libraries-1.4.321.0.tar.gz 625949 BLAKE2B b283c2a716472d77ba12f07221f043afeb457615538b92a4544f478ec9face954ec970a6443d56b5f949a051d047d913e94a5ce5666bcf754b0a6eb7b1292cda SHA512 764e3150aee1a13a81ff66f8b8690c4aa1874bd91a811470ff7dd5cd8d0e79d10f7e4d84962300bdf19405944d7b69c2840175d319e0718bfb19841373bcba22
+DIST vulkan-utility-libraries-1.4.328.0.tar.gz 1241530 BLAKE2B 21cafbcf066b69340d7c36851f9fb3174c7795d40160e52327a01f0a5800ab8cdf119d5eba8f12199476be32503d60509308b9acfc3b6033c4c86c5558fc649a SHA512 598c03da7c4a76be6ee95d74fc4a00908b0dc3165e82ec0eec01c329c0a79654d827f8eeada8d9b4e173443b848c15cd71c23c965ac799d7d4d354cf76cc68e9

dev-util/vulkan-utility-libraries/vulkan-utility-libraries-1.4.328.0.ebuild

@@ -0,0 +1,55 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MY_PN=Vulkan-Utility-Libraries
+PYTHON_COMPAT=( python3_{11..14} )
+PYTHON_REQ_USE="xml(+)"
+inherit cmake-multilib dot-a python-any-r1
+
+if [[ ${PV} == *9999* ]]; then
+	EGIT_REPO_URI="https://github.com/KhronosGroup/${MY_PN}.git"
+	inherit git-r3
+else
+	EGIT_COMMIT="vulkan-sdk-${PV}"
+	SRC_URI="https://github.com/KhronosGroup/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
+	S="${WORKDIR}"/${MY_PN}-${EGIT_COMMIT}
+fi
+
+DESCRIPTION="Share code across various Vulkan repositories"
+HOMEPAGE="https://github.com/KhronosGroup/Vulkan-Utility-Libraries"
+
+LICENSE="Apache-2.0"
+SLOT="0"
+IUSE="test"
+RESTRICT="!test? ( test )"
+
+DEPEND="~dev-util/vulkan-headers-${PV}
+	test? (
+		dev-cpp/gtest
+		>=dev-cpp/magic_enum-0.9.7
+	)"
+BDEPEND="${PYTHON_DEPS}"
+
+PATCHES=(
+	"${FILESDIR}"/${PN}-1.4.313.0-magic_enum-0.9.7.patch
+)
+
+src_configure() {
+	lto-guarantee-fat
+	multilib-minimal_src_configure
+}
+
+multilib_src_configure() {
+	local mycmakeargs=(
+		-DBUILD_TESTS=$(usex test ON OFF)
+	)
+	cmake_src_configure
+}
+
+multilib_src_install_all() {
+	einstalldocs
+	strip-lto-bytecode
+}