diff --git a/dev-python/netcdf4/Manifest b/dev-python/netcdf4/Manifest
index cff6fbd68c1d..d0b3b78223c1 100644
--- a/dev-python/netcdf4/Manifest
+++ b/dev-python/netcdf4/Manifest
@@ -1 +1,2 @@
 DIST netcdf4-1.7.3.tar.gz 836095 BLAKE2B bab24504cf590a666c2c868c1732f431801f3a56d84919e4d3dfc8d166ac8dae034f69845cb3fd8f32001359c0bc7eab6f7759a78653b898275d15114f61aedc SHA512 1d7d9dfa99e820e83dab712550c4aeb85d5e5f0c6b61df75673d5dffe9eb3663d4020a0b02fb01acb27a06026e8f996beac3597a27d3a7088bf0a547b015fab8
+DIST netcdf4-1.7.4.tar.gz 838352 BLAKE2B 04c53f692234ebd5fba1e58cabacba337f70dfbc909aeb798b4663eb55446bed008bf783872325d4c99d4e2cfd856aa20194835d57e76669b84824cf216771d5 SHA512 e6021d3701cfb27a283592c5804e125b64adde541f60b1636ef5c1c604ea5eca3c4f9b72c72b0af958a341d876a991a5e3d45092ab1d0ed72384b7442cd8f425
diff --git a/dev-python/netcdf4/netcdf4-1.7.4.ebuild b/dev-python/netcdf4/netcdf4-1.7.4.ebuild
new file mode 100644
index 000000000000..6ea15e044be5
--- /dev/null
+++ b/dev-python/netcdf4/netcdf4-1.7.4.ebuild
@@ -0,0 +1,55 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=setuptools
+PYPI_PN=netCDF4
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1 optfeature pypi
+
+DESCRIPTION="Python/numpy interface to the netCDF C library"
+HOMEPAGE="
+	https://unidata.github.io/netcdf4-python/
+	https://github.com/unidata/netcdf4-python/
+	https://pypi.org/project/netCDF4/
+"
+
+LICENSE="MIT"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="blosc bzip2 mpi test szip zstd"
+RESTRICT="!test? ( test )"
+
+DEPEND="
+	dev-python/numpy[${PYTHON_USEDEP}]
+	sci-libs/hdf5:=
+	sci-libs/netcdf:=[blosc(-)=,bzip2(-)=,hdf5,mpi=,szip=,zstd(-)=]
+"
+RDEPEND="
+	${DEPEND}
+	dev-python/certifi[${PYTHON_USEDEP}]
+	dev-python/cftime[${PYTHON_USEDEP}]
+"
+BDEPEND="
+	dev-python/cython[${PYTHON_USEDEP}]
+	test? (
+		${RDEPEND}
+		dev-python/packaging[${PYTHON_USEDEP}]
+		>=dev-python/typing-extensions-4.15.0[${PYTHON_USEDEP}]
+		sci-libs/netcdf[tools(+)]
+	)
+"
+
+python_test() {
+	local -x NO_NET=1
+	cd test || die
+	"${EPYTHON}" run_all.py || die
+}
+
+pkg_postinst() {
+	optfeature "HDF4 support" sci-libs/hdf "sci-libs/netcdf[hdf]"
+	optfeature "OPeNDAP support" net-misc/curl "sci-libs/netcdf[dap]"
+}