mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-10 00:10:19 +03:00
6a3644bf2f
Done via: ``` git grep -l virtual/zlib$ | xargs sed -i -e 's@virtual/zlib$@&:=@' ``` Signed-off-by: Michał Górny <mgorny@gentoo.org>
71 lines
1.5 KiB
Bash
71 lines
1.5 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
inherit autotools python-single-r1
|
|
|
|
DESCRIPTION="Standalone file import filter library for spreadsheet documents"
|
|
HOMEPAGE="https://gitlab.com/orcus/orcus/blob/master/README.md"
|
|
|
|
if [[ ${PV} == *9999* ]]; then
|
|
MDDS_SLOT="1/3.0"
|
|
EGIT_REPO_URI="https://gitlab.com/orcus/orcus.git"
|
|
inherit git-r3
|
|
else
|
|
MDDS_SLOT="1/3.0"
|
|
# "404s" but serves HTML for 0.20.0
|
|
#SRC_URI="https://kohei.us/files/orcus/src/${P}.tar.xz"
|
|
SRC_URI="https://gitlab.com/api/v4/projects/orcus%2Forcus/packages/generic/source/${PV}/${P}.tar.gz"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~x86"
|
|
fi
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0/0.20" # based on SONAME of liborcus.so
|
|
IUSE="python +spreadsheet-model test tools"
|
|
|
|
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
dev-libs/boost:=[zlib(+)]
|
|
virtual/zlib:=
|
|
python? ( ${PYTHON_DEPS} )
|
|
spreadsheet-model? ( dev-libs/libixion:${SLOT} )
|
|
"
|
|
DEPEND="
|
|
${RDEPEND}
|
|
dev-util/mdds:${MDDS_SLOT}
|
|
"
|
|
|
|
PATCHES=(
|
|
"${FILESDIR}"/${PN}-0.19.2-boost-m4.patch
|
|
)
|
|
|
|
pkg_setup() {
|
|
use python && python-single-r1_pkg_setup
|
|
}
|
|
|
|
src_prepare() {
|
|
default
|
|
eautoreconf
|
|
}
|
|
|
|
src_configure() {
|
|
local myeconfargs=(
|
|
--without-benchmark
|
|
--disable-werror
|
|
$(use_enable python)
|
|
$(use_enable spreadsheet-model)
|
|
$(use_with tools)
|
|
)
|
|
econf "${myeconfargs[@]}"
|
|
}
|
|
|
|
src_install() {
|
|
default
|
|
use python && python_optimize
|
|
find "${D}" -name '*.la' -type f -delete || die
|
|
}
|