mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-11 00:07:51 +03:00
fe64a0d17c
dnspython supports DNS-over-HTTPS since 2.0.0 [1]. dnspython supports DNS-over-QUIC since 2.3.0 [2]. [1]: https://dnspython.readthedocs.io/en/latest/whatsnew.html#id12 [2]: https://dnspython.readthedocs.io/en/latest/whatsnew.html#id8 Closes: https://bugs.gentoo.org/962204 Signed-off-by: Bertrand Jacquin <bertrand@jacquin.bzh> Part-of: https://github.com/gentoo/gentoo/pull/43622 Closes: https://github.com/gentoo/gentoo/pull/43622 Signed-off-by: Michał Górny <mgorny@gentoo.org>
62 lines
1.2 KiB
Bash
62 lines
1.2 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_P=${P/_}
|
|
DESCRIPTION="DNS toolkit for Python"
|
|
HOMEPAGE="
|
|
https://www.dnspython.org/
|
|
https://github.com/rthalley/dnspython/
|
|
https://pypi.org/project/dnspython/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/rthalley/dnspython/archive/v${PV/_}.tar.gz
|
|
-> ${MY_P}.gh.tar.gz
|
|
"
|
|
S=${WORKDIR}/${MY_P}
|
|
|
|
LICENSE="ISC"
|
|
SLOT="0"
|
|
IUSE="dnssec examples https quic"
|
|
|
|
RDEPEND="
|
|
dnssec? (
|
|
>=dev-python/cryptography-45[${PYTHON_USEDEP}]
|
|
)
|
|
>=dev-python/idna-2.1[${PYTHON_USEDEP}]
|
|
https? (
|
|
>=dev-python/httpx-0.26.0[${PYTHON_USEDEP}]
|
|
>=dev-python/h2-4.1.0[${PYTHON_USEDEP}]
|
|
)
|
|
quic? ( >=dev-python/aioquic-0.9.25[${PYTHON_USEDEP}] )
|
|
"
|
|
# note: skipping DoH test deps because they require Internet anyway
|
|
BDEPEND="
|
|
test? (
|
|
>=dev-python/cryptography-45[${PYTHON_USEDEP}]
|
|
>=dev-python/quart-trio-0.11.0[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
EPYTEST_PLUGINS=()
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
local -x NO_INTERNET=1
|
|
epytest
|
|
}
|
|
|
|
python_install_all() {
|
|
distutils-r1_python_install_all
|
|
if use examples; then
|
|
dodoc -r examples
|
|
docompress -x /usr/share/doc/${PF}/examples
|
|
fi
|
|
}
|