mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-08 00:05:33 +03:00
0ad96e879b
Result of running the command: grep --include="*.ebuild" -r . -e 'KEYWORDS=.*[" ]sparc' -l | xargs ekeyword ~sparc Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
66 lines
1.6 KiB
Bash
66 lines
1.6 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{11..13} pypy3_11 )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="Python library to work with pdf files based on qpdf"
|
|
HOMEPAGE="
|
|
https://github.com/pikepdf/pikepdf/
|
|
https://pypi.org/project/pikepdf/
|
|
"
|
|
|
|
LICENSE="MPL-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc x86"
|
|
IUSE="big-endian"
|
|
|
|
# Check QPDF_MIN_VERSION in pyproject.toml on bumps, as well as
|
|
# https://qpdf.readthedocs.io/en/stable/release-notes.html.
|
|
DEPEND="
|
|
>=app-text/qpdf-11.5.0:0=
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
dev-python/deprecated[${PYTHON_USEDEP}]
|
|
>=dev-python/lxml-4.0[${PYTHON_USEDEP}]
|
|
dev-python/packaging[${PYTHON_USEDEP}]
|
|
>=dev-python/pillow-10.0.1[lcms,${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
>=dev-python/pybind11-2.13.6[${PYTHON_USEDEP}]
|
|
>=dev-python/setuptools-77.0.3[${PYTHON_USEDEP}]
|
|
>=dev-python/setuptools-scm-7.0.5[${PYTHON_USEDEP}]
|
|
test? (
|
|
>=dev-python/attrs-20.2.0[${PYTHON_USEDEP}]
|
|
>=dev-python/numpy-1.21.0[${PYTHON_USEDEP}]
|
|
>=dev-python/pillow-5.0.0[${PYTHON_USEDEP},jpeg,lcms,tiff]
|
|
>=dev-python/psutil-5.9[${PYTHON_USEDEP}]
|
|
>=dev-python/python-dateutil-2.8.1[${PYTHON_USEDEP}]
|
|
!big-endian? (
|
|
>=dev-python/python-xmp-toolkit-2.0.1[${PYTHON_USEDEP}]
|
|
)
|
|
media-libs/tiff[zlib]
|
|
)
|
|
"
|
|
|
|
EPYTEST_PLUGINS=( hypothesis pytest-timeout )
|
|
distutils_enable_tests pytest
|
|
|
|
src_prepare() {
|
|
distutils-r1_src_prepare
|
|
|
|
sed -e '/-n auto/d' -i pyproject.toml || die
|
|
}
|
|
|
|
python_test() {
|
|
# work around https://github.com/pikepdf/pikepdf/issues/660
|
|
local -x TMPDIR=/tmp
|
|
epytest
|
|
}
|