mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-10 00:10:19 +03:00
66 lines
1.7 KiB
Bash
66 lines
1.7 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
# please keep this ebuild at EAPI 8 -- sys-apps/portage dep
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{11..14} pypy3_11 )
|
|
PYTHON_REQ_USE="threads(+)"
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="HTTP library for human beings"
|
|
HOMEPAGE="
|
|
https://requests.readthedocs.io/
|
|
https://github.com/psf/requests/
|
|
https://pypi.org/project/requests/
|
|
"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~arm64-macos ~x64-macos"
|
|
IUSE="socks5 test-rust"
|
|
|
|
RDEPEND="
|
|
>=dev-python/certifi-2017.4.17[${PYTHON_USEDEP}]
|
|
<dev-python/charset-normalizer-4[${PYTHON_USEDEP}]
|
|
<dev-python/idna-4[${PYTHON_USEDEP}]
|
|
<dev-python/urllib3-3[${PYTHON_USEDEP}]
|
|
socks5? ( >=dev-python/pysocks-1.5.6[${PYTHON_USEDEP}] )
|
|
"
|
|
|
|
BDEPEND="
|
|
test? (
|
|
>=dev-python/pysocks-1.5.6[${PYTHON_USEDEP}]
|
|
test-rust? (
|
|
dev-python/trustme[${PYTHON_USEDEP}]
|
|
)
|
|
)
|
|
"
|
|
|
|
EPYTEST_PLUGINS=( pytest-{httpbin,mock} )
|
|
EPYTEST_XDIST=1
|
|
distutils_enable_tests pytest
|
|
|
|
python_test() {
|
|
local EPYTEST_DESELECT=(
|
|
# Internet (doctests)
|
|
requests/__init__.py::requests
|
|
requests/api.py::requests.api.request
|
|
requests/models.py::requests.models.PreparedRequest
|
|
requests/sessions.py::requests.sessions.Session
|
|
# require IPv4 interface in 10.* range
|
|
tests/test_requests.py::TestTimeout::test_connect_timeout
|
|
tests/test_requests.py::TestTimeout::test_total_timeout_connect
|
|
)
|
|
|
|
if ! has_version "dev-python/trustme[${PYTHON_USEDEP}]"; then
|
|
EPYTEST_DESELECT+=(
|
|
tests/test_requests.py::TestRequests::test_https_warnings
|
|
)
|
|
fi
|
|
|
|
epytest
|
|
}
|