mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-09 00:07:57 +03:00
daad312350
This program is usually *always* available in gentoo, being a direct
dependency of portage, and some other system packages. Still, it's
useful to list dependencies like this in bootstrap scenarios.
It is my belief that this dependency was introduced in 5.3, with the
following commit:
59b2bd05f5
Closes: https://bugs.gentoo.org/963902
Signed-off-by: Esteve Varela Colominas <esteve.varela@gmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44088
Closes: https://github.com/gentoo/gentoo/pull/44088
Signed-off-by: Sam James <sam@gentoo.org>
54 lines
1.4 KiB
Bash
54 lines
1.4 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
ETYPE="headers"
|
|
H_SUPPORTEDARCH="alpha amd64 arc arm arm64 csky hexagon hppa ia64 loong m68k microblaze mips nios2 openrisc ppc ppc64 riscv s390 sh sparc x86 xtensa"
|
|
inherit kernel-2
|
|
detect_version
|
|
|
|
PATCH_PV=${PV} # to ease testing new versions against not existing patches
|
|
PATCH_VER="1"
|
|
PATCH_DEV="sam"
|
|
SRC_URI="
|
|
${KERNEL_URI}
|
|
${PATCH_VER:+https://dev.gentoo.org/~${PATCH_DEV}/distfiles/sys-kernel/linux-headers/gentoo-headers-${PATCH_PV}-${PATCH_VER}.tar.xz}
|
|
"
|
|
S="${WORKDIR}/linux-${PV}"
|
|
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86 ~amd64-linux ~x86-linux"
|
|
|
|
BDEPEND="
|
|
app-arch/xz-utils
|
|
dev-lang/perl
|
|
net-misc/rsync
|
|
"
|
|
|
|
src_unpack() {
|
|
# Avoid kernel-2_src_unpack
|
|
default
|
|
}
|
|
|
|
src_prepare() {
|
|
local PATCHES=()
|
|
[[ -n ${PATCH_VER} ]] && PATCHES+=( "${WORKDIR}"/${PATCH_PV} )
|
|
PATCHES+=( "${FILESDIR}"/${PN}-sparc-move-struct-termio-to-asm-termios.h.patch )
|
|
|
|
# TODO: May need forward porting to newer versions
|
|
use elibc_musl && PATCHES+=(
|
|
"${FILESDIR}"/${PN}-5.15-remove-inclusion-sysinfo.h.patch
|
|
)
|
|
|
|
# Avoid kernel-2_src_prepare
|
|
default
|
|
}
|
|
|
|
src_install() {
|
|
kernel-2_src_install
|
|
|
|
find "${ED}" \( -name '.install' -o -name '*.cmd' \) -delete || die
|
|
# Delete empty directories
|
|
find "${ED}" -empty -type d -delete || die
|
|
}
|