mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-09 00:07:57 +03:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389808700bd0f4343ee04888f0ef179d2
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
82 lines
1.5 KiB
Bash
82 lines
1.5 KiB
Bash
# Copyright 2019-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit meson vala
|
|
|
|
DESCRIPTION="glib library for communicating with snapd"
|
|
HOMEPAGE="https://snapcraft.io/"
|
|
SRC_URI="https://github.com/canonical/snapd-glib/archive/refs/tags/${PV}.tar.gz -> ${P}.tar.gz"
|
|
|
|
LICENSE="LGPL-3"
|
|
SLOT="0/1"
|
|
KEYWORDS="amd64"
|
|
|
|
IUSE="doc introspection qml qt6 vala"
|
|
REQUIRED_USE="
|
|
qml? ( qt6 )
|
|
vala? ( introspection )
|
|
"
|
|
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
sys-devel/gettext
|
|
qt6? ( dev-qt/qttools:6[linguist] )
|
|
"
|
|
|
|
DEPEND="
|
|
dev-libs/json-glib
|
|
dev-libs/glib:2
|
|
dev-util/glib-utils
|
|
net-libs/libsoup:3.0
|
|
doc? (
|
|
dev-build/gtk-doc-am
|
|
dev-util/gi-docgen
|
|
dev-util/gtk-doc
|
|
)
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
|
|
qml? (
|
|
qt6? ( dev-qt/qtdeclarative:6 )
|
|
)
|
|
qt6? (
|
|
dev-qt/qtbase:6[network,widgets]
|
|
)
|
|
vala? ( $(vala_depend) )
|
|
"
|
|
|
|
RDEPEND="${DEPEND}
|
|
app-containers/snapd
|
|
"
|
|
|
|
PATCHES=(
|
|
# https://github.com/canonical/snapd-glib/commit/6620406c7280a1f56b53151131350050df8d24af
|
|
"${FILESDIR}/${P}-install-missing-header.patch"
|
|
)
|
|
|
|
pkg_setup() {
|
|
vala_setup
|
|
}
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
"$(meson_use doc docs)"
|
|
"$(meson_use introspection)"
|
|
"$(meson_use qml qml-bindings)"
|
|
"$(meson_use qt6)"
|
|
"$(meson_use vala vala-bindings)"
|
|
-Dsoup2=false
|
|
-Dqt5=false
|
|
)
|
|
|
|
meson_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
if use doc; then
|
|
dodir /usr/share/gtk-doc/html/
|
|
mv "${ED}/usr/share/doc/${PN}" "${ED}/usr/share/gtk-doc/html/${PF}" || die
|
|
fi
|
|
}
|