mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-09 00:07:57 +03:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389808700bd0f4343ee04888f0ef179d2
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
70 lines
1.9 KiB
Bash
70 lines
1.9 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit flag-o-matic gnome.org meson virtualx
|
|
|
|
DESCRIPTION="Javascript bindings for GNOME"
|
|
HOMEPAGE="https://gjs.guide"
|
|
|
|
LICENSE="MIT || ( MPL-1.1 LGPL-2+ GPL-2+ )"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 ~loong ~ppc64 ~riscv x86"
|
|
IUSE="examples readline sysprof test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
# <glib-2.86.0 for bug #963815
|
|
RDEPEND="
|
|
>=dev-libs/glib-2.66.0:2
|
|
<dev-libs/glib-2.86.0:2
|
|
dev-libs/libffi:=
|
|
>=dev-libs/gobject-introspection-1.82.0-r2:=
|
|
dev-lang/spidermonkey:128
|
|
x11-libs/cairo[X,glib]
|
|
readline? ( sys-libs/readline:0= )
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
sysprof? ( >=dev-util/sysprof-capture-3.40.1:4 )
|
|
test? (
|
|
sys-apps/dbus
|
|
>=x11-libs/gtk+-3.20:3[introspection]
|
|
)
|
|
"
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
src_configure() {
|
|
append-cppflags -DG_DISABLE_CAST_CHECKS
|
|
|
|
# On musl, it's required that either gjs, pixman or gnome-shell to be built
|
|
# with a larger stack otherwise librsvg fails to render a particular SVG, as
|
|
# a result we fail to get gdm or gnome-shell running (greeted with a fail
|
|
# whale screen). The bug has been reported to librsvg. This is ideally just
|
|
# a temporary workaround until we understand what exactly needs a larger
|
|
# stack size, as it's not sufficient to do just librsvg.
|
|
#
|
|
# Please refer to:
|
|
# https://gitlab.gnome.org/GNOME/librsvg/-/issues/686
|
|
# https://gitlab.gnome.org/GNOME/librsvg/-/issues/874
|
|
#
|
|
# TODO: Find an actual fix instead of increasing the stack
|
|
use elibc_musl && append-ldflags -Wl,-z,stack-size=2097152
|
|
|
|
# FIXME: add systemtap/dtrace support, like in glib:2
|
|
local emesonargs=(
|
|
$(meson_feature readline)
|
|
$(meson_feature sysprof profiler)
|
|
-Dinstalled_tests=false
|
|
$(meson_use !test skip_dbus_tests)
|
|
$(meson_use !test skip_gtk_tests)
|
|
-Db_pch=True # TODO this has to go
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
src_test() {
|
|
virtx meson_src_test
|
|
}
|