mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-09 00:07:57 +03:00
62 lines
1.3 KiB
Bash
62 lines
1.3 KiB
Bash
# Copyright 2024-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
|
|
inherit distutils-r1
|
|
|
|
MY_P="opentelemetry-python-${PV}"
|
|
DESCRIPTION="OpenTelemetry Python API"
|
|
HOMEPAGE="
|
|
https://opentelemetry.io/
|
|
https://pypi.org/project/opentelemetry-api/
|
|
https://github.com/open-telemetry/opentelemetry-python/
|
|
"
|
|
SRC_URI="
|
|
https://github.com/open-telemetry/opentelemetry-python/archive/refs/tags/v${PV}.tar.gz
|
|
-> ${MY_P}.gh.tar.gz
|
|
"
|
|
S="${WORKDIR}/${MY_P}/${PN}"
|
|
|
|
LICENSE="Apache-2.0"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm64 x86"
|
|
|
|
RDEPEND="
|
|
>=dev-python/importlib-metadata-6.0[${PYTHON_USEDEP}]
|
|
>=dev-python/typing-extensions-4.5.0[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
test? (
|
|
dev-python/typing-extensions[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
EPYTEST_PLUGINS=()
|
|
distutils_enable_tests pytest
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# Unnecessary restriction
|
|
sed -i -e '/importlib-metadata/s:, < [0-9.]*::' pyproject.toml || die
|
|
}
|
|
|
|
python_test() {
|
|
cp -a "${BUILD_DIR}"/{install,test} || die
|
|
local -x PATH=${BUILD_DIR}/test/usr/bin:${PATH}
|
|
|
|
for dep in opentelemetry-semantic-conventions opentelemetry-sdk \
|
|
tests/opentelemetry-test-utils
|
|
do
|
|
pushd "${WORKDIR}/${MY_P}/${dep}" >/dev/null || die
|
|
distutils_pep517_install "${BUILD_DIR}"/test
|
|
popd >/dev/null || die
|
|
done
|
|
|
|
epytest
|
|
}
|