mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-08 00:05:33 +03:00
b288d27d59
Hit by the top-level asm partitioning changes. Not worrying about this for now as more work is ongoing. Keeping bug open as we want to revisit this befor release. Bug: https://bugs.gentoo.org/965545 Signed-off-by: Sam James <sam@gentoo.org>
69 lines
1.6 KiB
Bash
69 lines
1.6 KiB
Bash
# Copyright 2018-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{10..14} )
|
|
VIRTUALX_REQUIRED=manual
|
|
|
|
inherit meson-multilib flag-o-matic python-any-r1 toolchain-funcs virtualx
|
|
|
|
DESCRIPTION="The GL Vendor-Neutral Dispatch library"
|
|
HOMEPAGE="https://gitlab.freedesktop.org/glvnd/libglvnd"
|
|
if [[ ${PV} = 9999 ]]; then
|
|
inherit git-r3
|
|
EGIT_REPO_URI="https://gitlab.freedesktop.org/glvnd/${PN}.git"
|
|
else
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~m68k ~mips ppc ppc64 ~riscv ~s390 ~sparc x86"
|
|
SRC_URI="https://gitlab.freedesktop.org/glvnd/${PN}/-/archive/v${PV}/${PN}-v${PV}.tar.bz2 -> ${P}.tar.bz2"
|
|
S=${WORKDIR}/${PN}-v${PV}
|
|
fi
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
IUSE="test X"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
BDEPEND="${PYTHON_DEPS}
|
|
test? ( X? ( ${VIRTUALX_DEPEND} ) )"
|
|
RDEPEND="
|
|
!media-libs/mesa[-libglvnd(+)]
|
|
X? (
|
|
x11-libs/libX11[${MULTILIB_USEDEP}]
|
|
x11-libs/libXext[${MULTILIB_USEDEP}]
|
|
)"
|
|
DEPEND="${RDEPEND}
|
|
X? ( x11-base/xorg-proto )"
|
|
|
|
PATCHES=( "${FILESDIR}/${PN}-1.7.0-backport-pr291.patch" )
|
|
|
|
src_prepare() {
|
|
default
|
|
sed -i -e "/^PLATFORM_SYMBOLS/a '__gentoo_check_ldflags__'," \
|
|
bin/symbols-check.py || die
|
|
}
|
|
|
|
src_configure() {
|
|
# Workaround for bug #965545
|
|
tc-is-gcc && [[ $(gcc-major-version) -eq 16 ]] && filter-lto
|
|
meson-multilib_src_configure
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
$(meson_feature X x11)
|
|
$(meson_feature X glx)
|
|
)
|
|
use elibc_musl && emesonargs+=( -Dtls=false )
|
|
|
|
meson_src_configure
|
|
}
|
|
|
|
multilib_src_test() {
|
|
if use X; then
|
|
virtx meson_src_test
|
|
else
|
|
meson_src_test
|
|
fi
|
|
}
|