mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-11 00:07:51 +03:00
01b7e9ba55
Removing remote-id as most of GNOME doesn't include it Signed-off-by: zyxhere💭 <zyx@envs.net> Part-of: https://github.com/gentoo/gentoo/pull/44128 Closes: https://github.com/gentoo/gentoo/pull/44128 Signed-off-by: Sam James <sam@gentoo.org>
67 lines
1.5 KiB
Bash
67 lines
1.5 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit gnome2 multilib-minimal
|
|
|
|
DESCRIPTION="C++ interface for GTK+"
|
|
HOMEPAGE="https://gtkmm.gnome.org/en/index.html"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="2.4"
|
|
KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~loong ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux"
|
|
IUSE="doc examples test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-cpp/glibmm-2.34.1:2[${MULTILIB_USEDEP}]
|
|
>=x11-libs/gtk+-2.24.15:2[${MULTILIB_USEDEP}]
|
|
>=x11-libs/gdk-pixbuf-2.28:2[${MULTILIB_USEDEP}]
|
|
>=dev-cpp/atkmm-2.22.7:0[${MULTILIB_USEDEP}]
|
|
>=dev-cpp/cairomm-1.10.0-r1:0[${MULTILIB_USEDEP}]
|
|
>=dev-cpp/pangomm-2.34.0:1.4[${MULTILIB_USEDEP}]
|
|
>=dev-libs/libsigc++-2.3.2:2[${MULTILIB_USEDEP}]
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
doc? (
|
|
app-text/doxygen
|
|
dev-libs/libxslt
|
|
media-gfx/graphviz
|
|
)
|
|
"
|
|
|
|
src_prepare() {
|
|
if ! use test; then
|
|
# don't waste time building tests
|
|
sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
|
|
|| die "sed 1 failed"
|
|
fi
|
|
|
|
if ! use examples; then
|
|
# don't waste time building examples
|
|
sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
|
|
|| die "sed 2 failed"
|
|
fi
|
|
|
|
gnome2_src_prepare
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
ECONF_SOURCE="${S}" \
|
|
gnome2_src_configure \
|
|
--enable-api-atkmm \
|
|
$(multilib_native_use_enable doc documentation)
|
|
}
|
|
|
|
multilib_src_install() {
|
|
gnome2_src_install
|
|
}
|
|
|
|
multilib_src_install_all() {
|
|
local DOCS=( AUTHORS ChangeLog PORTING NEWS README )
|
|
einstalldocs
|
|
}
|