mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-09 00:07:57 +03:00
c14ae7a3c5
drop py3.10 fix c23/musl removing bundled getopt Closes: https://bugs.gentoo.org/895848 Closes: https://bugs.gentoo.org/944133 Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr> Part-of: https://github.com/gentoo/gentoo/pull/43850 Signed-off-by: Sam James <sam@gentoo.org>
83 lines
1.6 KiB
Bash
83 lines
1.6 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_EXT=1
|
|
DISTUTILS_OPTIONAL=1
|
|
DISTUTILS_SINGLE_IMPL=1
|
|
DISTUTILS_USE_PEP517=setuptools
|
|
PYTHON_COMPAT=( python3_{11..13} )
|
|
|
|
inherit distutils-r1 qmake-utils
|
|
|
|
DESCRIPTION="Graphical file and directories comparator and merge tool"
|
|
HOMEPAGE="https://furius.ca/xxdiff/ https://github.com/blais/xxdiff"
|
|
COMMIT="a5593c1c675fb79d0ec2b6e353abba1fb0179aa7"
|
|
SRC_URI="https://github.com/blais/xxdiff/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
|
|
S="${WORKDIR}/${PN}-${COMMIT}"
|
|
|
|
LICENSE="GPL-2"
|
|
SLOT="0"
|
|
KEYWORDS="~amd64 ~x86"
|
|
IUSE="scripts"
|
|
REQUIRED_USE="scripts? ( ${PYTHON_REQUIRED_USE} )"
|
|
|
|
RDEPEND="
|
|
dev-qt/qtbase:6[gui,widgets]
|
|
scripts? ( ${PYTHON_DEPS} )
|
|
"
|
|
DEPEND="
|
|
${RDEPEND}
|
|
app-alternatives/yacc
|
|
"
|
|
BDEPEND="
|
|
scripts? (
|
|
${DISTUTILS_DEPS}
|
|
${PYTHON_DEPS}
|
|
)
|
|
"
|
|
|
|
pkg_setup() {
|
|
use scripts && python-single-r1_pkg_setup
|
|
}
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# don't use bundled getopt #944133
|
|
sed -e '/getopt.*/d' -i src/xxdiff.pro || die
|
|
|
|
use scripts && distutils-r1_src_prepare
|
|
}
|
|
|
|
src_configure() {
|
|
pushd src >/dev/null || die
|
|
# mimic src/Makefile.bootstrap
|
|
eqmake6
|
|
cat Makefile.extra >> Makefile || die
|
|
popd || die
|
|
}
|
|
|
|
src_compile() {
|
|
emake -C src MAKEDIR=.
|
|
|
|
use scripts && distutils-r1_src_compile
|
|
}
|
|
|
|
src_install() {
|
|
local DOCS=( CHANGES README* TODO doc/*.txt src/doc.txt tools )
|
|
local HTML_DOCS=( doc/*.{png,html} src/doc.html )
|
|
|
|
dobin bin/xxdiff
|
|
doman "${S}"/src/xxdiff.1
|
|
|
|
if use scripts; then
|
|
distutils-r1_src_install
|
|
# no port to py3
|
|
rm "${ED}"/usr/bin/termdiff || die
|
|
fi
|
|
|
|
einstalldocs
|
|
}
|