mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-06 00:05:54 +03:00
bd0ee727e0
Update done using: ``` git grep -l sys-libs/zlib dev-* | xargs sed -i -e s@sys-libs/zlib@virtual/zlib@g git diff --name-only | xargs copybump git diff --name-only | xargs grep -l PYTHON_COMPAT | xargs gpy-impl -@dead pkgcheck scan --commits -c SourcingCheck,VisibilityCheck --exit error ``` Followed by manual revert in dev-python/zlib-ng where it accidentally caught sys-libs/zlib-ng dependencies. Signed-off-by: Michał Górny <mgorny@gentoo.org>
56 lines
1.1 KiB
Bash
56 lines
1.1 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
inherit cmake xdg-utils
|
|
|
|
DESCRIPTION="CD and DVD image access library"
|
|
HOMEPAGE="https://cdemu.sourceforge.io"
|
|
SRC_URI="https://download.sourceforge.net/cdemu/libmirage/${P}.tar.xz"
|
|
|
|
LICENSE="GPL-2+"
|
|
SLOT="0/11"
|
|
KEYWORDS="amd64 x86"
|
|
IUSE="doc +introspection"
|
|
|
|
DEPEND="
|
|
>=app-arch/bzip2-1:=
|
|
>=app-arch/xz-utils-5:=
|
|
>=dev-libs/glib-2.38:2
|
|
>=media-libs/libsamplerate-0.1:=
|
|
>=media-libs/libsndfile-1.0:=
|
|
virtual/zlib:=
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
|
|
"
|
|
RDEPEND="
|
|
${DEPEND}
|
|
"
|
|
BDEPEND="
|
|
dev-util/desktop-file-utils
|
|
dev-util/intltool
|
|
sys-devel/gettext
|
|
virtual/pkgconfig
|
|
doc? ( dev-util/gtk-doc )
|
|
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
|
|
"
|
|
|
|
DOCS=( AUTHORS README )
|
|
|
|
src_configure() {
|
|
local mycmakeargs=(
|
|
-DGTKDOC_ENABLED="$(usex doc)"
|
|
-DINTROSPECTION_ENABLED="$(usex introspection)"
|
|
-DPOST_INSTALL_HOOKS=OFF # avoid sandbox violation, #487304
|
|
)
|
|
cmake_src_configure
|
|
}
|
|
|
|
pkg_postinst() {
|
|
xdg_mimeinfo_database_update
|
|
}
|
|
|
|
pkg_postrm() {
|
|
xdg_mimeinfo_database_update
|
|
}
|