mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-11 00:07:51 +03:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389808700bd0f4343ee04888f0ef179d2
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
64 lines
1.4 KiB
Bash
64 lines
1.4 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
|
|
inherit flag-o-matic meson-multilib python-any-r1 vala
|
|
|
|
if [[ ${PV} = 9999* ]]; then
|
|
EGIT_REPO_URI="https://github.com/martinpitt/${PN}.git"
|
|
inherit git-r3
|
|
else
|
|
SRC_URI="https://github.com/martinpitt/umockdev/releases/download/${PV}/${P}.tar.xz"
|
|
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
|
|
fi
|
|
|
|
DESCRIPTION="Mock hardware devices for creating unit tests"
|
|
HOMEPAGE="https://github.com/martinpitt/umockdev/"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="0"
|
|
IUSE="test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
net-libs/libpcap[${MULTILIB_USEDEP}]
|
|
virtual/libudev:=[${MULTILIB_USEDEP}]
|
|
>=dev-libs/glib-2.32:2[${MULTILIB_USEDEP}]
|
|
>=dev-libs/gobject-introspection-1.82.0-r2:=
|
|
"
|
|
DEPEND="${RDEPEND}
|
|
test? (
|
|
${PYTHON_DEPS}
|
|
dev-libs/libgudev:=[${MULTILIB_USEDEP}]
|
|
)
|
|
"
|
|
BDEPEND="
|
|
$(vala_depend)
|
|
app-arch/xz-utils
|
|
virtual/pkgconfig
|
|
"
|
|
|
|
pkg_setup() {
|
|
use test && python-any-r1_pkg_setup
|
|
}
|
|
|
|
src_prepare() {
|
|
default
|
|
vala_setup
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
# https://gcc.gnu.org/bugzilla/show_bug.cgi?id=101270
|
|
filter-flags -fno-semantic-interposition
|
|
|
|
export VALAC="$(type -P valac-$(vala_best_api_version))"
|
|
meson_src_configure
|
|
}
|
|
|
|
multilib_src_test() {
|
|
export SLOW_TESTBED_FACTOR=10
|
|
meson_src_test --num-processes=1 --timeout-multiplier=10 --setup installed
|
|
}
|