mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-21 00:08:09 +03:00
0ad96e879b
Result of running the command: grep --include="*.ebuild" -r . -e 'KEYWORDS=.*[" ]sparc' -l | xargs ekeyword ~sparc Signed-off-by: Arthur Zamarin <arthurzam@gentoo.org>
73 lines
1.8 KiB
Bash
73 lines
1.8 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
DISTUTILS_USE_PEP517=hatchling
|
|
# py3.14: https://github.com/pydantic/pydantic/issues/11613
|
|
PYTHON_COMPAT=( pypy3_11 python3_{11..13} )
|
|
|
|
inherit distutils-r1 pypi
|
|
|
|
DESCRIPTION="Data parsing and validation using Python type hints"
|
|
HOMEPAGE="
|
|
https://github.com/pydantic/pydantic/
|
|
https://pypi.org/project/pydantic/
|
|
"
|
|
|
|
LICENSE="MIT"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 arm arm64 ~loong ppc ppc64 ~riscv ~s390 ~sparc x86"
|
|
|
|
RDEPEND="
|
|
>=dev-python/annotated-types-0.6.0[${PYTHON_USEDEP}]
|
|
~dev-python/pydantic-core-2.33.2[${PYTHON_USEDEP}]
|
|
>=dev-python/typing-extensions-4.12.2[${PYTHON_USEDEP}]
|
|
>=dev-python/typing-inspection-0.4.0[${PYTHON_USEDEP}]
|
|
dev-python/tzdata[${PYTHON_USEDEP}]
|
|
"
|
|
BDEPEND="
|
|
>=dev-python/hatch-fancy-pypi-readme-22.5.0[${PYTHON_USEDEP}]
|
|
test? (
|
|
$(python_gen_cond_dep '
|
|
dev-python/cloudpickle[${PYTHON_USEDEP}]
|
|
' 'python3*')
|
|
dev-python/dirty-equals[${PYTHON_USEDEP}]
|
|
>=dev-python/email-validator-2.0.0[${PYTHON_USEDEP}]
|
|
>=dev-python/faker-18.13.0[${PYTHON_USEDEP}]
|
|
>=dev-python/jsonschema-4.23.0[${PYTHON_USEDEP}]
|
|
dev-python/pytest-mock[${PYTHON_USEDEP}]
|
|
dev-python/pytz[${PYTHON_USEDEP}]
|
|
dev-python/rich[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
|
|
distutils_enable_tests pytest
|
|
|
|
src_prepare() {
|
|
sed -i -e '/benchmark/d' pyproject.toml || die
|
|
distutils-r1_src_prepare
|
|
}
|
|
|
|
python_test() {
|
|
local EPYTEST_DESELECT=(
|
|
# -Werror, sigh
|
|
tests/test_types_typeddict.py::test_readonly_qualifier_warning
|
|
)
|
|
local EPYTEST_IGNORE=(
|
|
# require pytest-examples
|
|
tests/test_docs.py
|
|
# benchmarks
|
|
tests/benchmarks
|
|
)
|
|
|
|
if ! has_version "dev-python/cloudpickle[${PYTHON_USEDEP}]"; then
|
|
EPYTEST_IGNORE+=(
|
|
tests/test_pickle.py
|
|
)
|
|
fi
|
|
|
|
local -x PYTEST_DISABLE_PLUGIN_AUTOLOAD=1
|
|
epytest -p pytest_mock
|
|
}
|