mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-11 00:07:51 +03:00
d83e25b6a5
sed -E '/dev-libs\/gobject-introspection(:=|\s|$|-[0-9]|\[)/ { s/(>=)?dev-libs\/gobject-introspection(-[0-9.r-]*)?/>=dev-libs\/gobject-introspection-1.82.0-r2/ }' */*/*.ebuild -i
+ manually going over to undo the false positives or if the version
requirement was higher.
Bug: https://bugs.gentoo.org/947058
See-Also: ae37e3f389808700bd0f4343ee04888f0ef179d2
Signed-off-by: Alfred Wingate <parona@protonmail.com>
Part-of: https://github.com/gentoo/gentoo/pull/44336
Closes: https://github.com/gentoo/gentoo/pull/44336
Signed-off-by: Sam James <sam@gentoo.org>
63 lines
1.2 KiB
Bash
63 lines
1.2 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
|
|
inherit gnome.org meson python-r1 vala xdg
|
|
|
|
DESCRIPTION="Git library for GLib"
|
|
HOMEPAGE="https://wiki.gnome.org/Projects/Libgit2-glib"
|
|
|
|
LICENSE="LGPL-2+"
|
|
SLOT="0"
|
|
KEYWORDS="amd64 ~arm64 ~ppc64 ~riscv x86"
|
|
IUSE="gtk-doc python +ssh +vala"
|
|
REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/gobject-introspection-1.82.0-r2:=
|
|
>=dev-libs/glib-2.44.0:2
|
|
>=dev-libs/libgit2-0.26.0:=[ssh?]
|
|
python? (
|
|
${PYTHON_DEPS}
|
|
dev-python/pygobject:3[${PYTHON_USEDEP}]
|
|
)
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
dev-util/glib-utils
|
|
virtual/pkgconfig
|
|
gtk-doc? ( dev-util/gi-docgen )
|
|
vala? ( $(vala_depend) )
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
sed -i -e '/meson_python_compile.py/d' meson.build || die
|
|
}
|
|
|
|
src_configure() {
|
|
local emesonargs=(
|
|
$(meson_use gtk-doc gtk_doc)
|
|
-Dintrospection=true
|
|
-Dpython=false # we install python scripts manually
|
|
$(meson_use ssh)
|
|
$(meson_use vala vapi)
|
|
)
|
|
|
|
use vala && vala_setup
|
|
meson_src_configure
|
|
}
|
|
|
|
src_install() {
|
|
meson_src_install
|
|
|
|
if use python ; then
|
|
python_moduleinto gi.overrides
|
|
python_foreach_impl python_domodule libgit2-glib/Ggit.py
|
|
fi
|
|
}
|