mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-09 00:07:57 +03:00
01b7e9ba55
Removing remote-id as most of GNOME doesn't include it Signed-off-by: zyxhere💭 <zyx@envs.net> Part-of: https://github.com/gentoo/gentoo/pull/44128 Closes: https://github.com/gentoo/gentoo/pull/44128 Signed-off-by: Sam James <sam@gentoo.org>
54 lines
1.4 KiB
Bash
54 lines
1.4 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{11..14} )
|
|
inherit gnome.org meson-multilib python-any-r1 virtualx
|
|
|
|
DESCRIPTION="C++ interface for GTK+"
|
|
HOMEPAGE="https://gtkmm.gnome.org/en/index.html"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="3.0"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux"
|
|
|
|
IUSE="aqua gtk-doc test wayland X"
|
|
REQUIRED_USE="|| ( aqua wayland X )"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-cpp/atkmm-2.24.2:0[gtk-doc?,${MULTILIB_USEDEP}]
|
|
>=dev-cpp/cairomm-1.12.0:0[gtk-doc?,${MULTILIB_USEDEP}]
|
|
>=dev-cpp/glibmm-2.54.0:2[gtk-doc?,${MULTILIB_USEDEP}]
|
|
>=dev-cpp/pangomm-2.38.2:1.4[gtk-doc?,${MULTILIB_USEDEP}]
|
|
>=dev-libs/libsigc++-2.3.2:2[gtk-doc?,${MULTILIB_USEDEP}]
|
|
>=media-libs/libepoxy-1.2[${MULTILIB_USEDEP}]
|
|
>=x11-libs/gdk-pixbuf-2.35.5:2[${MULTILIB_USEDEP}]
|
|
>=x11-libs/gtk+-3.24.0:3[aqua?,wayland?,X=,${MULTILIB_USEDEP}]
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
virtual/pkgconfig
|
|
gtk-doc? (
|
|
app-text/doxygen[dot]
|
|
dev-lang/perl
|
|
dev-libs/libxslt
|
|
)
|
|
${PYTHON_DEPS}
|
|
"
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
-Dbuild-atkmm-api=true
|
|
-Dbuild-demos=false
|
|
$(meson_native_use_bool gtk-doc build-documentation)
|
|
$(meson_use test build-tests)
|
|
$(meson_use X build-x11-api)
|
|
)
|
|
meson_src_configure
|
|
}
|
|
|
|
multilib_src_test() {
|
|
virtx meson_src_test
|
|
}
|