mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2025-12-10 00:10:19 +03:00
01b7e9ba55
Removing remote-id as most of GNOME doesn't include it Signed-off-by: zyxhere💭 <zyx@envs.net> Part-of: https://github.com/gentoo/gentoo/pull/44128 Closes: https://github.com/gentoo/gentoo/pull/44128 Signed-off-by: Sam James <sam@gentoo.org>
55 lines
1.2 KiB
Bash
55 lines
1.2 KiB
Bash
# Copyright 1999-2025 Gentoo Authors
|
|
# Distributed under the terms of the GNU General Public License v2
|
|
|
|
EAPI=8
|
|
PYTHON_COMPAT=( python3_{10..13} )
|
|
inherit gnome.org meson-multilib python-any-r1
|
|
|
|
DESCRIPTION="C++ interface for glib2"
|
|
HOMEPAGE="https://gtkmm.gnome.org/en/index.html"
|
|
|
|
LICENSE="LGPL-2.1+"
|
|
SLOT="2"
|
|
KEYWORDS="~alpha amd64 arm arm64 ~hppa ~loong ~mips ppc ppc64 ~riscv ~sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
|
|
IUSE="gtk-doc debug test"
|
|
RESTRICT="!test? ( test )"
|
|
|
|
RDEPEND="
|
|
>=dev-libs/libsigc++-2.9.1:2[${MULTILIB_USEDEP}]
|
|
>=dev-libs/glib-2.61.2:2[${MULTILIB_USEDEP}]
|
|
"
|
|
DEPEND="${RDEPEND}"
|
|
BDEPEND="
|
|
${PYTHON_DEPS}
|
|
virtual/pkgconfig
|
|
gtk-doc? (
|
|
app-text/doxygen[dot]
|
|
dev-lang/perl
|
|
dev-perl/XML-Parser
|
|
dev-libs/libxslt
|
|
media-gfx/graphviz
|
|
)
|
|
"
|
|
|
|
src_prepare() {
|
|
default
|
|
|
|
# giomm_tls_client requires FEATURES=-network-sandbox and glib-networking rdep
|
|
sed -i -e '/giomm_tls_client/d' tests/meson.build || die
|
|
|
|
if ! use test; then
|
|
sed -i -e "/^subdir('tests')/d" meson.build || die
|
|
fi
|
|
}
|
|
|
|
multilib_src_configure() {
|
|
local emesonargs=(
|
|
-Dwarnings=min
|
|
-Dbuild-deprecated-api=true
|
|
$(meson_native_use_bool gtk-doc build-documentation)
|
|
$(meson_use debug debug-refcounting)
|
|
-Dbuild-examples=false
|
|
)
|
|
meson_src_configure
|
|
}
|