bcachefs: update to v1.37.4

sys-fs/bcachefs-kmod/Manifest

@@ -0,0 +1,2 @@
+DIST bcachefs-tools-1.37.4.tar.sign 833 BLAKE2B 0cec7399acf3f7efb44c746d032c557f40817dd8b09f4de01b541ac70a6c98375c6310f18b9223a0b7b9c18f45dedb2c57769d1285225969179be99631e5500f SHA512 e371ff6860db44f2490817cf498fa590402cc2cae3f7ee383e1dd556aed3443463f815b699880c38eb46c0bef04a9a5a13c0ecb9ec96f133a50a32a71eff1bfa
+DIST bcachefs-tools-1.37.4.tar.zst 1663281 BLAKE2B 6d1eabae9528d209979e10b742653e1e1a019141a6c0f0bbc5bb2b97c1faa9d4c8ca59b701617f6410926799f0b58ac5bd7f26ce3f9077e34adc4c8e07e32bb9 SHA512 48e030d31c9135399072b8ae408abdb9af43cf02b100a5f6019ee00d70db3ba02d94d0e3880d2394f79f72a5b2b57122ae58bb564218d1a7453783d1cd166eca

sys-fs/bcachefs-kmod/bcachefs-kmod-1.37.4.ebuild

@@ -0,0 +1,107 @@
+# Copyright 1999-2026 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+MODULES_INITRAMFS_IUSE=+initramfs
+
+inherit linux-mod-r1 unpacker verify-sig
+
+MY_PN="bcachefs-tools"
+
+DESCRIPTION="Linux bcachefs kernel module for sys-fs/bcachefs-tools"
+HOMEPAGE="https://bcachefs.org/"
+if [[ ${PV} == "9999" ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://evilpiepirate.org/git/bcachefs-tools.git"
+else
+	SRC_URI="https://evilpiepirate.org/bcachefs-tools/bcachefs-tools-${PV}.tar.zst"
+	SRC_URI+=" verify-sig? ( https://evilpiepirate.org/bcachefs-tools/bcachefs-tools-${PV}.tar.sign )"
+	KEYWORDS="~amd64 ~arm64"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+
+IUSE="debug verify-sig"
+
+MODULES_KERNEL_MIN=6.16
+
+VERIFY_SIG_OPENPGP_KEY_PATH=/usr/share/openpgp-keys/kentoverstreet.asc
+
+BDEPEND="
+	>=sys-kernel/linux-headers-6.16
+	verify-sig? ( >=sec-keys/openpgp-keys-kentoverstreet-20241012 )
+"
+
+pkg_setup() {
+	# See https://github.com/koverstreet/bcachefs-tools/blob/master/libbcachefs/Kconfig
+	local CONFIG_CHECK="
+		BLOCK
+		EXPORTFS
+		CRC32
+		CRC64
+		FS_POSIX_ACL
+		LZ4_COMPRESS
+		LZ4_DECOMPRESS
+		LZ4HC_COMPRESS
+		ZLIB_DEFLATE
+		ZLIB_INFLATE
+		ZSTD_COMPRESS
+		ZSTD_DECOMPRESS
+		CRYPTO_LIB_SHA256
+		CRYPTO_LIB_CHACHA
+		CRYPTO_LIB_POLY1305
+		KEYS
+		RAID6_PQ
+		XOR_BLOCKS
+		XXHASH
+		SYMBOLIC_ERRNAME
+	"
+	use debug && CONFIG_CHECK+="
+		DEBUG_INFO
+		FRAME_POINTER
+		!DEBUG_INFO_REDUCED
+	"
+	linux-mod-r1_pkg_setup
+}
+
+src_unpack() {
+	# Upstream signs the uncompressed tarball
+	if use verify-sig; then
+		einfo "Unpacking ${P}.tar.zst ..."
+		verify-sig_verify_detached - "${DISTDIR}"/${MY_PN}-${PV}.tar.sign \
+			< <(zstd -fdc "${DISTDIR}"/${MY_PN}-${PV}.tar.zst | tee >(tar -xf -))
+		assert "Unpack failed"
+	fi
+
+	if [[ ${PV} == "9999" ]]; then
+		git-r3_src_unpack
+	else
+		unpacker ${MY_PN}-${PV}.tar.zst
+	fi
+
+}
+
+src_prepare() {
+	default
+
+	# Live builds will overwrite .version with git-describe output
+	echo "${PV}" > .version || die
+	emake DESTDIR="${WORKDIR}" PREFIX="/module" install_dkms
+}
+
+src_compile() {
+	local dirs=( "${WORKDIR}/module/src/${PN%-*}-"* )
+	local module_src="${dirs[0]}"
+
+	[[ -d "${module_src}" ]] || die
+
+	local modlist=( "bcachefs=:${module_src}:${module_src}/src/fs/bcachefs" )
+	local modargs=(
+		KDIR=${KV_OUT_DIR}
+	)
+
+	linux-mod-r1_src_compile
+}

sys-fs/bcachefs-kmod/metadata.xml

@@ -0,0 +1,20 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+	<maintainer type="person">
+		<email>alex@millerson.name</email>
+		<name>Alexander Miroshnichenko</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>falbrechtskirchinger@gmail.com</email>
+		<name>Florian Albrechtskirchinger</name>
+	</maintainer>
+	<maintainer type="person">
+		<email>flow@gentoo.org</email>
+		<name>Florian Schmaus</name>
+	</maintainer>
+	<upstream>
+		<remote-id type="github">koverstreet/bcachefs-tools</remote-id>
+		<changelog>https://github.com/koverstreet/bcachefs-tools/blob/master/Changelog.mdwn</changelog>
+	</upstream>
+</pkgmetadata>