dev-util/kdstatemachineeditor: add 2.1.0, fix qt-6.9

this release includes fix for qt-6.9

some variables are no longer required
set dot explicity for doxygen, even if graphviz is already required
remove ${ED} for compress -x
remove a static-lib for debuginterface

Closes: https://bugs.gentoo.org/957226
Signed-off-by: Nicolas PARLANT <nicolas.parlant@parhuet.fr>
Part-of: https://github.com/gentoo/gentoo/pull/42112
Closes: https://github.com/gentoo/gentoo/pull/42112
Signed-off-by: Sam James <sam@gentoo.org>

dev-util/kdstatemachineeditor/Manifest

@@ -1 +1,2 @@
 DIST KDStateMachineEditor-v2.0.0.tar.gz 1008123 BLAKE2B 5aa60276b91bfec01528300d6d80872a586baf1ef5f76b0b2afb058bed84d4a2400a302b9bbd647cb82e69ca9daad5f1fc14d1b758bdce88010d51a147444e39 SHA512 dedd7166f434689cd5acf4ee3172169d3f77182269d3187f0a7a12966467dd5c7733e3ff64cd1fd03b0f3866c2aafa37cc3f2d7b8a3f4a5d8a7592da039de7af
+DIST kdstatemachineeditor-2.1.0.tar.gz 1012048 BLAKE2B 0af13049e5a9ef983eb3f9ddda2cf344d0f0326deb2e08a72dbde1da15e4ff795ce3ffc624eb28de32805f75cc2fd30326a3f93f704ffaa1af72b28c0dbaa7ab SHA512 2027dd27d296f13c46d3efb11653d26d832e573b65fe98e982d320aa034df9df386b822d0a2dadacd230b0594d125bfd1dfa1443487dccb6e9074efcd7abe59b

dev-util/kdstatemachineeditor/kdstatemachineeditor-2.1.0.ebuild

@@ -0,0 +1,99 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake
+
+MY_PN="KDStateMachineEditor"
+
+DESCRIPTION="Framework for creating Qt State Machine metacode using graphical user interfaces"
+HOMEPAGE="https://github.com/KDAB/KDStateMachineEditor"
+
+if [[ ${PV} == *9999* ]] ; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/KDAB/KDStateMachineEditor.git"
+else
+	SRC_URI="https://github.com/KDAB/KDStateMachineEditor/releases/download/v${PV}/${P}.tar.gz"
+	KEYWORDS="~amd64"
+	S="${WORKDIR}/${MY_PN}-${PV}"
+fi
+
+LICENSE="LGPL-2.1"
+SLOT="0"
+IUSE="doc gui test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-qt/qtbase:6[gui,network,opengl,widgets]
+	dev-qt/qtdeclarative:6[widgets]
+	dev-qt/qtremoteobjects:6
+	dev-qt/qtscxml:6
+	media-gfx/graphviz
+	gui? ( dev-qt/qt5compat:6[qml] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	doc? (
+		app-text/doxygen[dot]
+		dev-qt/qttools:6[assistant]
+	)
+	gui? ( dev-util/patchelf )
+"
+
+src_prepare() {
+	# set TEST_DATA_DIR for application env instead of test env.
+	if use gui; then
+		sed -e 's:${CMAKE_CURRENT_SOURCE_DIR}/data:'"${EPREFIX}"'/usr/share/'"${PN}"'/data:' \
+			-i CMakeLists.txt || die
+	fi
+
+	cmake_src_prepare
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DKDSME_DOCS=$(usex doc)
+		-DKDSME_EXAMPLES=OFF
+		-DKDSME_INTERNAL_GRAPHVIZ=OFF
+	)
+
+	use doc && mycmakeargs+=(
+		# prevent ${PF}-qt6
+		-DQCH_INSTALL_DIR="${EPREFIX}/usr/share/doc/${PF}/"
+	)
+
+	if use gui || use test; then
+		mycmakeargs+=( -DBUILD_TESTING=ON )
+	else
+		mycmakeargs+=( -DBUILD_TESTING=OFF )
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	# skip tests that use scxml files in modified TEST_DATA_DIR
+	use gui && CMAKE_SKIP_TESTS=(
+		test_layouter
+		test_scxmlimport
+	)
+	local -x QT_QPA_PLATFORM=offscreen
+	KDE_DEBUG=1 cmake_src_test
+}
+
+src_install() {
+	cmake_src_install
+
+	rm "${ED}"/usr/$(get_libdir)/*.a || die
+
+	if use gui; then
+		patchelf --remove-rpath "${BUILD_DIR}"/bin/${PN} || die
+		dobin "${BUILD_DIR}"/bin/${PN}
+		mkdir -p "${ED}"/usr/share/${PN} || die
+		cp -R data "${ED}"/usr/share/${PN}/ || die
+	fi
+
+	use doc && docompress -x /usr/share/doc/${PF}/${PN}{-api.qch,.tags}
+}