gui-wm/labwc: new package, add 0.9.2, 9999

Signed-off-by: Viorel Munteanu <ceamac@gentoo.org>

gui-wm/labwc/Manifest

@@ -0,0 +1 @@
+DIST labwc-0.9.2.tar.gz 533516 BLAKE2B 2e771bcef5a05988d57c8bd6deef6392271bc68f1caf347de1d96e39c711b1519d0ec679ea730b3f8b8779e7a5bbd39950563fcd15d6ec4700e3e83bcbfe792c SHA512 4d58a7156886d80483eb16dcce4754de802910846cbfe640fae5048bf6a6c4a3803022f85e1e4fd4dd334f240cd91577b8be7563ed0f1a52e6369dd4ed2278b0

gui-wm/labwc/labwc-0.9.2.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Openbox alternative for wayland"
+HOMEPAGE="https://github.com/labwc/labwc https://labwc.github.io/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/labwc/labwc"
+else
+	SRC_URI="https://github.com/labwc/labwc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="X icons nls svg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/wayland-1.19
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/libxml2:2
+	gui-libs/wlroots:0.19[X?]
+	media-libs/libpng:=
+	x11-libs/cairo[X?]
+	x11-libs/libdrm:=
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango[X?]
+	x11-libs/pixman
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-wm
+	)
+	icons? ( gui-libs/libsfdo )
+	nls? ( sys-devel/gettext )
+	svg? ( gnome-base/librsvg:2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/wayland-protocols-1.35
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-util/cmocka )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		$(meson_feature X xwayland)
+		$(meson_feature nls)
+		$(meson_feature svg)
+		$(meson_feature icons icon)
+		$(meson_feature test)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die
+}

gui-wm/labwc/labwc-9999.ebuild

@@ -0,0 +1,70 @@
+# Copyright 2021-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg
+
+DESCRIPTION="Openbox alternative for wayland"
+HOMEPAGE="https://github.com/labwc/labwc https://labwc.github.io/"
+
+if [[ ${PV} == 9999 ]]; then
+	inherit git-r3
+	EGIT_REPO_URI="https://github.com/labwc/labwc"
+else
+	SRC_URI="https://github.com/labwc/labwc/archive/${PV}.tar.gz -> ${P}.tar.gz"
+	KEYWORDS="~amd64"
+fi
+
+LICENSE="GPL-2"
+SLOT="0"
+IUSE="X icons nls svg test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	>=dev-libs/wayland-1.19
+	dev-libs/glib:2
+	dev-libs/libinput:=
+	dev-libs/libxml2:2
+	gui-libs/wlroots:0.19[X?]
+	media-libs/libpng:=
+	x11-libs/cairo[X?]
+	x11-libs/libdrm:=
+	x11-libs/libxkbcommon[X?]
+	x11-libs/pango[X?]
+	x11-libs/pixman
+	X? (
+		x11-base/xwayland
+		x11-libs/libxcb:0=
+		x11-libs/xcb-util-wm
+	)
+	icons? ( gui-libs/libsfdo )
+	nls? ( sys-devel/gettext )
+	svg? ( gnome-base/librsvg:2 )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	app-text/scdoc
+	>=dev-libs/wayland-protocols-1.35
+	virtual/pkgconfig
+	nls? ( sys-devel/gettext )
+	test? ( dev-util/cmocka )
+"
+
+src_configure() {
+	local emesonargs=(
+		-Dman-pages=enabled
+		$(meson_feature X xwayland)
+		$(meson_feature nls)
+		$(meson_feature svg)
+		$(meson_feature icons icon)
+		$(meson_feature test)
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}"/usr/share/doc/${PN} "${ED}"/usr/share/doc/${PF} || die
+}

gui-wm/labwc/metadata.xml

@@ -0,0 +1,14 @@
+<?xml version="1.0" encoding="UTF-8"?>
+<!DOCTYPE pkgmetadata SYSTEM "https://www.gentoo.org/dtd/metadata.dtd">
+<pkgmetadata>
+  <maintainer type="person">
+    <email>ceamac@gentoo.org</email>
+    <name>Viorel Munteanu</name>
+  </maintainer>
+  <upstream>
+    <remote-id type="github">labwc/labwc</remote-id>
+  </upstream>
+  <use>
+    <flag name="icons">Add support for window icons. Icons will only be displayed with USE=svg enabled</flag>
+  </use>
+</pkgmetadata>