kde-frameworks/extra-cmake-modules: 6.13.0 version bump

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

kde-frameworks/extra-cmake-modules/Manifest

@@ -1,2 +1,3 @@
 DIST extra-cmake-modules-6.10.0.tar.xz 324580 BLAKE2B 9c6b3491f30609cd47d056c325e38ab190fd240a5e3018457f545034bc3853f4abcfb5694a6a18734e29614bacb2021a7850e3e3b8663d6bd47ffef361fea77a SHA512 3ebf2cd4bcaa82a90374411f3313f84fa632b73f3c8b8109d545d0289c99d940705e72ded498393738342db4becbe9055eecb673891969652915d75cdcb6368d
 DIST extra-cmake-modules-6.12.0.tar.xz 328004 BLAKE2B dbe11fb48fa2dbb4ad6917e3321f8fb1f4c2133e55d6587c2668ed7ec4f6a7dc53b8602ec9abe6d286611d39d8cac60b0ace19fd5b749d861d2d7ddb95c5baba SHA512 84de5442f921809a557cbbad887e118dba3f54c6bd3b8abe11760436861ae79ab239325e7d97e03f67a5782afacb59a534b5ddd1a7a80c4898c985b15022cd72
+DIST extra-cmake-modules-6.13.0.tar.xz 328572 BLAKE2B 2dd0b8890e2a6b7f5696409a0c886491b1b97910773011f7b4b885371eabaabb025b0e2ff85d1a3852b11a9ee782243c0899196fa46c9732105f44801901c090 SHA512 7e6c89e959d6ec5d69f5353a01e0971d94e7d5386c3724a8c3530d9bc7cb4d53d8f1d67bfc76e866af12f4260940d094439fc01a23a55ad0cc74661797345884

kde-frameworks/extra-cmake-modules/extra-cmake-modules-6.13.0.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{10..13} )
+QTMIN=6.7.2
+inherit cmake frameworks.kde.org python-any-r1
+
+DESCRIPTION="Extra modules and scripts for CMake"
+HOMEPAGE="https://invent.kde.org/frameworks/extra-cmake-modules"
+
+LICENSE="BSD"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~ppc ~ppc64 ~riscv ~x86"
+IUSE="doc test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="app-arch/libarchive[bzip2]"
+DEPEND="
+	test? (
+		>=dev-qt/qtbase-${QTMIN}:6[dbus,gui]
+		>=dev-qt/qtdeclarative-${QTMIN}:6
+	)
+"
+BDEPEND="
+	doc? (
+		${PYTHON_DEPS}
+		$(python_gen_any_dep 'dev-python/sphinx[${PYTHON_USEDEP}]')
+		>=dev-qt/qttools-${QTMIN}:6[assistant]
+	)
+	test? (
+		>=dev-qt/qtbase-${QTMIN}:6
+		>=dev-qt/qttools-${QTMIN}:6[linguist]
+	)
+"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-5.49.0-no-fatal-warnings.patch"
+	"${FILESDIR}/${PN}-5.93.0-skip-ecm_add_test-early.patch"
+	"${FILESDIR}/${PN}-5.245.0-disable-qmlplugindump.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-appstreamtest.patch"
+	"${FILESDIR}/${PN}-6.5.0-disable-git-commit-hooks.patch"
+)
+
+python_check_deps() {
+	python_has_version "dev-python/sphinx[${PYTHON_USEDEP}]"
+}
+
+pkg_setup() {
+	use doc && python-any-r1_pkg_setup
+}
+
+src_configure() {
+	local mycmakeargs=(
+		-DDOC_INSTALL_DIR=/usr/share/doc/"${PF}"
+		-DBUILD_QTHELP_DOCS=$(usex doc)
+		-DBUILD_HTML_DOCS=$(usex doc)
+		-DBUILD_MAN_DOCS=$(usex doc)
+		-DBUILD_TESTING=$(usex test)
+	)
+	if use test; then
+		mycmakeargs+=( -DQT_MAJOR_VERSION=6 ) # bug 938316
+	fi
+
+	cmake_src_configure
+}
+
+src_test() {
+	local CMAKE_SKIP_TESTS=(
+		# passes, but then breaks src_install
+		ECMToolchainAndroidTest
+		# broken, bug #627806
+		ECMPoQmToolsTest
+		# can not possibly succeed in releases, bug #764953
+		KDEFetchTranslations
+	)
+	# possible race condition with multiple jobs, bug #701854
+	cmake_src_test -j1
+}