millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-05 00:08:05 +03:00
Code Packages Projects Releases Wiki Activity

dev-python/ipykernel: Bump to 6.23.3

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2023-06-24 07:18:31 +02:00
parent b924997b9b
commit 0bc263f7a2
2 changed files with 78 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/ipykernel/Manifest
View File

@@ -1,2 +1,3 @@
DIST ipykernel-6.23.1.tar.gz 153370 BLAKE2B 654998d46851bcc55d3c0c9c6134f3fcf8c81c2552d5af6dcdbd791e1ac98ed223a59aafc9b7b4260345f8730d243d3c82d4e19e03935a368a0a0154de547cb0 SHA512 8f3921789c837f7c046eed4ffdaade2273b6491cfd97b9a192a256966a66d58c1ad93cbfa69a5e933e052fa35c2c7a4671a652ee9f2bb2cca5a156c79df0f14f
DIST ipykernel-6.23.2.tar.gz 154126 BLAKE2B 75289aed8e3eff98519fc309a802e440b4486a89f8f62717facb85c04fa03405bb0b1200f5c61e07dc6c96e4efda67473a50cc677fc438b7ec8f72157f084859 SHA512 f3c05d145aea0ada4a11486357895b9938d64cbebc4a7265a6bd1246dfbe0a3cba1ad4ef1de900115ce24d6a0bdfda71eb6d7a06980366f41c410e22f73ebdec
DIST ipykernel-6.23.3.tar.gz 154264 BLAKE2B 7fc9fd9dbbc928aaee2cb8549b097ce87896c0e08c326e4d724a39a04af934e62f5c02fef35908d8d5cf3bf6cb6abcbcc175d771515a2df0835f7003385e85d5 SHA512 c5de85de9e944b3441911b8af289496705078b56572b4a91f1c3fd402a30cf3957bda3420b810b6cbe80ebd05c22cdc1024c4cbbc838a5638d537104105b2056

77
dev-python/ipykernel/ipykernel-6.23.3.ebuild Normal file
View File

@@ -0,0 +1,77 @@
# Copyright 1999-2023 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=hatchling
PYTHON_COMPAT=( python3_{10..11} )
PYTHON_REQ_USE="threads(+)"
inherit distutils-r1 pypi virtualx
DESCRIPTION="IPython Kernel for Jupyter"
HOMEPAGE="
https://github.com/ipython/ipykernel/
https://pypi.org/project/ipykernel/
"
LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~loong ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
RDEPEND="
>=dev-python/comm-0.1.1[${PYTHON_USEDEP}]
>=dev-python/debugpy-1.6.5[${PYTHON_USEDEP}]
>=dev-python/ipython-7.23.1[${PYTHON_USEDEP}]
>=dev-python/jupyter-client-8[${PYTHON_USEDEP}]
>=dev-python/jupyter-core-4.12[${PYTHON_USEDEP}]
>=dev-python/matplotlib-inline-0.1[${PYTHON_USEDEP}]
dev-python/nest_asyncio[${PYTHON_USEDEP}]
dev-python/packaging[${PYTHON_USEDEP}]
dev-python/psutil[${PYTHON_USEDEP}]
>=dev-python/pyzmq-20[${PYTHON_USEDEP}]
>=dev-python/tornado-6.1[${PYTHON_USEDEP}]
>=dev-python/traitlets-5.4.0[${PYTHON_USEDEP}]
"
# RDEPEND seems specifically needed in BDEPEND, at least jupyter
# bug #816486
BDEPEND="
${RDEPEND}
test? (
dev-python/flaky[${PYTHON_USEDEP}]
dev-python/pytest-asyncio[${PYTHON_USEDEP}]
dev-python/pytest-timeout[${PYTHON_USEDEP}]
dev-python/ipyparallel[${PYTHON_USEDEP}]
)
"
distutils_enable_tests pytest
src_prepare() {
sed -i -e 's:^TIMEOUT = .*:TIMEOUT = 120:' ipykernel/tests/*.py || die
distutils-r1_src_prepare
}
python_compile() {
distutils-r1_python_compile
# Use python3 in kernel.json configuration, bug #784764
sed -i -e '/python3.[0-9]\+/s//python3/' \
"${BUILD_DIR}/install${EPREFIX}/usr/share/jupyter/kernels/python3/kernel.json" || die
}
src_test() {
local EPYTEST_DESELECT=(
# TODO
ipykernel/tests/test_debugger.py::test_attach_debug
ipykernel/tests/test_debugger.py::test_breakpoint_in_cell_with_leading_empty_lines
ipykernel/tests/test_debugger.py::test_rich_inspect_at_breakpoint
ipykernel/tests/test_debugger.py::test_rich_inspect_not_at_breakpoint
ipykernel/tests/test_debugger.py::test_set_breakpoints
ipykernel/tests/test_debugger.py::test_stop_on_breakpoint
ipykernel/tests/test_debugger.py::test_copy_to_globals
# hangs?
ipykernel/tests/test_eventloop.py::test_tk_loop
)
virtx distutils-r1_src_test
}