app-text/crengine-ng: current snapshot

Fixed a bug: when loading an rtf, encoding was sometimes wrong

Signed-off-by: Andrey Grozin <grozin@gentoo.org>

app-text/crengine-ng/Manifest

@@ -1,2 +1,3 @@
 DIST crengine-ng-0.9.10.tar.bz2 3416315 BLAKE2B ea1e4aa13c8ab233f26a2878a138cbdf8c371cdcdb86103a91bf09eb3ae3f060da76b5d32fb6d70236b3f9c787876d3f87a4caed353a51942f78b9cd25c11202 SHA512 7cb51ebaf7a62ce996f84deed2d61eef2b5adc76743755aa33e13d53a00409eaba41898f1f613973d3f361529d661952bca690c239f1e7536fcb153d120df83d
+DIST crengine-ng-0.9.10_p1.tar.bz2 3520115 BLAKE2B cceeba21ccd0c0e4c753c894fe1abf96ce3d972559b6713a20c049e02ca55a1cae7590d55ef28c9219ebd2d845dfd2ffd51580155a37e091c22a0f30298b45ec SHA512 3294483c9b8e8814d6652eff24fbb2e9e74a535734049751c5eaa7efaaff915587a5258aebcb8b6df779d635f0e459cd5ca23c4993f4ecffa6f2036f853b55eb
 DIST freefont-otf-20120503.tar.gz 4487813 BLAKE2B a280bef885bc71897a8475814602d7537b05d14a70e5857acd1007bc0a074be9db1e08fbd63fcabf3fde7874391bdd319d00b213e29b203d474fb320e91b82a2 SHA512 cee9a573b17ccc689b61f0925fb6624d58e3a3369d996e379e70c3a4cd750429d68c14c85fbcab4381101c8f4bf56730ef40e0045fdd79647019db41b4ec74fd

app-text/crengine-ng/crengine-ng-0.9.10_p1.ebuild

@@ -0,0 +1,78 @@
+# Copyright 1999-2024 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+inherit cmake
+
+DESCRIPTION="Cross-platform library designed to implement e-book readers"
+HOMEPAGE="https://gitlab.com/coolreader-ng/crengine-ng"
+SRC_URI="https://dev.gentoo.org/~grozin/${P}.tar.bz2
+	test? ( mirror://gnu/freefont/freefont-otf-20120503.tar.gz )"
+
+LICENSE="GPL-2+"
+SLOT="0/6-beta1"
+KEYWORDS="~amd64 ~arm64 ~x86"
+IUSE="+png +jpeg +gif +svg +chm +harfbuzz +fontconfig +libunibreak +fribidi +zstd +libutf8proc static-libs test"
+
+RESTRICT="!test? ( test )"
+
+CDEPEND="sys-libs/zlib
+	png? ( media-libs/libpng:0 )
+	jpeg? ( media-libs/libjpeg-turbo )
+	>=media-libs/freetype-2.10.0
+	harfbuzz? ( media-libs/harfbuzz:=[truetype] )
+	libunibreak? ( dev-libs/libunibreak:= )
+	fribidi? ( dev-libs/fribidi )
+	zstd? ( app-arch/zstd:= )
+	libutf8proc? ( dev-libs/libutf8proc:= )
+	fontconfig? ( media-libs/fontconfig )"
+
+RDEPEND="${CDEPEND}"
+DEPEND="
+	${RDEPEND}
+	test? ( dev-cpp/gtest
+		app-arch/zip )
+"
+BDEPEND="virtual/pkgconfig
+	${CDEPEND}"
+
+src_prepare() {
+	cmake_src_prepare
+	if use test; then
+		mkdir -p "${BUILD_DIR}/crengine/tests/fonts/"
+		cp -p "${WORKDIR}/freefont-20120503/"*.otf "${BUILD_DIR}/crengine/tests/fonts/"
+	fi
+}
+
+src_configure() {
+	CMAKE_BUILD_TYPE="Release"
+	local mycmakeargs=(
+		-DCRE_BUILD_SHARED=ON
+		-DCRE_BUILD_STATIC=$(usex static-libs)
+		-DUSE_COLOR_BACKBUFFER=ON
+		-DWITH_LIBPNG=$(usex png)
+		-DWITH_LIBJPEG=$(usex jpeg)
+		-DWITH_FREETYPE=ON
+		-DWITH_HARFBUZZ=$(usex harfbuzz)
+		-DWITH_LIBUNIBREAK=$(usex libunibreak)
+		-DWITH_FRIBIDI=$(usex fribidi)
+		-DWITH_ZSTD=$(usex zstd)
+		-DWITH_UTF8PROC=$(usex libutf8proc)
+		-DUSE_GIF=$(usex gif)
+		-DUSE_NANOSVG=$(usex svg)
+		-DUSE_CHM=$(usex chm)
+		-DUSE_ANTIWORD=ON
+		-DUSE_FONTCONFIG=$(usex fontconfig)
+		-DUSE_SHASUM=OFF
+		-DUSE_CMARK_GFM=ON
+		-DBUILD_TOOLS=OFF
+		-DENABLE_UNITTESTING=$(usex test)
+		-DOFFLINE_BUILD_MODE=ON
+	)
+	cmake_src_configure
+}
+
+src_test() {
+	cd "${BUILD_DIR}/crengine/tests"
+	./unittests
+}