mirror of
https://github.com/gentoo-mirror/gentoo.git
synced 2026-01-09 00:10:21 +03:00
dev-python/translate-toolkit: Bump to 3.16.2
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
@@ -1,3 +1,4 @@
|
||||
DIST translate-3.15.6.gh.tar.gz 1176856 BLAKE2B 4d23c254f89b84098f0e97dd6ba726129cedda3fc7bf7fad6d3171b5e66817bbf07025d8d1c2f8e7a5d643903ddc13668909fd06888fbd6fa152c83734be8791 SHA512 7881c6aba835003efb67ab0cf1f1420d1d4928d62fa04a6f15a49f49a5bb4d42eadbc3ae9b7dbe3ecbd756333a054c41f1f0fd45d9f6aedba609931233b691b1
|
||||
DIST translate-3.16.0.gh.tar.gz 1180120 BLAKE2B 11b173dc2990f14f5c83b55ddd05bf1ca660542ccac9cc234a13f443882f5c62fff80383a1200fc589c22fb34cc18feffb38165bf0127b3e29c750cf76462e30 SHA512 e4a556bc901edf8e1c86351ba28865a9063efd4b138a0f227d35301a4f0cc4b356a2aa04a4faa9d111c12a322fedff1b124b1b24db649f4c8e5a98b0ded96e69
|
||||
DIST translate-3.16.1.gh.tar.gz 1180456 BLAKE2B ff4ac6c8e21a611c0079902acebd2d6113a67767aff53634db6109d9ba70c2cb1fde5c3c267d108c8a67020b8d7354e6bb1df8469a01985c2347b5410281685a SHA512 73f2c50da384896955e04bb7a9cfc49fd0ae33b5b94478ca806e5857aff2a4dd5644185d0c8e720b9ad9c473565521ec8d054aca09fa1a63630c6ab00b82929b
|
||||
DIST translate-3.16.2.gh.tar.gz 1182285 BLAKE2B bc61eb5ff86586582f2c78be292345cc4cda54cfbb6e6687a8c54cbaf4634933c464548b6f42d5da916d0e92596d61767d79f8a2db8c0013766b0361ba0b2ec4 SHA512 58571a096f51d159334ae6c7fb242d35e05fcefeb7ce3a5984d89d8c4ede714432694ad03895352ee3450f40cd587431a92763be225fe6f0e680378bb1336317
|
||||
|
||||
127
dev-python/translate-toolkit/translate-toolkit-3.16.2.ebuild
Normal file
127
dev-python/translate-toolkit/translate-toolkit-3.16.2.ebuild
Normal file
@@ -0,0 +1,127 @@
|
||||
# Copyright 1999-2025 Gentoo Authors
|
||||
# Distributed under the terms of the GNU General Public License v2
|
||||
|
||||
EAPI=8
|
||||
|
||||
DISTUTILS_USE_PEP517=setuptools
|
||||
PYTHON_COMPAT=( python3_{11..14} )
|
||||
PYTHON_REQ_USE="sqlite"
|
||||
|
||||
inherit distutils-r1
|
||||
|
||||
MY_P=translate-${PV}
|
||||
DESCRIPTION="Toolkit to convert between many translation formats"
|
||||
HOMEPAGE="
|
||||
https://github.com/translate/translate/
|
||||
https://pypi.org/project/translate-toolkit/
|
||||
"
|
||||
SRC_URI="
|
||||
https://github.com/translate/translate/archive/${PV}.tar.gz
|
||||
-> ${MY_P}.gh.tar.gz
|
||||
"
|
||||
S="${WORKDIR}"/${MY_P}
|
||||
|
||||
LICENSE="GPL-2"
|
||||
SLOT="0"
|
||||
KEYWORDS="~amd64 ~arm64 ~x86"
|
||||
IUSE="+html +ical +ini +subtitles +yaml"
|
||||
|
||||
RDEPEND="
|
||||
app-text/iso-codes
|
||||
>=dev-python/chardet-3.0.4[${PYTHON_USEDEP}]
|
||||
dev-python/cheroot[${PYTHON_USEDEP}]
|
||||
>=dev-python/levenshtein-0.12.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/lxml-5.2.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/mistletoe-1.1.0[${PYTHON_USEDEP}]
|
||||
>=dev-python/pyparsing-3[${PYTHON_USEDEP}]
|
||||
dev-python/ruamel-yaml[${PYTHON_USEDEP}]
|
||||
>=dev-python/wcwidth-0.2.14[${PYTHON_USEDEP}]
|
||||
sys-devel/gettext
|
||||
html? ( dev-python/utidylib[${PYTHON_USEDEP}] )
|
||||
ical? ( dev-python/vobject[${PYTHON_USEDEP}] )
|
||||
ini? ( >=dev-python/iniparse-0.5[${PYTHON_USEDEP}] )
|
||||
subtitles? ( media-video/gaupol[${PYTHON_USEDEP}] )
|
||||
yaml? ( dev-python/pyyaml[${PYTHON_USEDEP}] )
|
||||
"
|
||||
# Technically, the test suite also has undeclared dependency
|
||||
# on dev-python/snapshottest but all the tests using it are broken
|
||||
# anyway, so we skip them.
|
||||
BDEPEND="
|
||||
test? (
|
||||
dev-python/phply[${PYTHON_USEDEP}]
|
||||
)
|
||||
"
|
||||
|
||||
EPYTEST_PLUGINS=()
|
||||
EPYTEST_XDIST=1
|
||||
distutils_enable_tests pytest
|
||||
|
||||
src_prepare() {
|
||||
distutils-r1_src_prepare
|
||||
|
||||
# strip unnecessary pins
|
||||
sed -i -e 's:,<[0-9.]*::' pyproject.toml || die
|
||||
}
|
||||
|
||||
src_test() {
|
||||
# unfortunately, this bad quality package doesn't support XDG_DATA_DIRS
|
||||
# correctly, so we need to reassemble all data files in a single directory
|
||||
local -x XDG_DATA_HOME=${T}/share
|
||||
cp -r translate/share "${T}/" || die
|
||||
cp -r "${ESYSROOT}"/usr/share/gaupol "${XDG_DATA_HOME}"/ || die
|
||||
|
||||
distutils-r1_src_test
|
||||
}
|
||||
|
||||
python_test() {
|
||||
local EPYTEST_DESELECT=(
|
||||
# Fails with network-sandbox (and even with it off but w/ softer fail)
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_open_office_to_xliff'
|
||||
'tests/xliff_conformance/test_xliff_conformance.py::test_po_to_xliff'
|
||||
# all tests based on snapshottest are broken and I'm too tired
|
||||
# to figure this out
|
||||
tests/translate/tools/test_pocount.py::test_{cases,output}
|
||||
tests/translate/tools/test_junitmsgfmt.py::test_output
|
||||
)
|
||||
local EPYTEST_IGNORE=(
|
||||
# unpackaged fluent.*
|
||||
tests/translate/storage/test_fluent.py
|
||||
# changes directory and does not change it back, sigh
|
||||
tests/odf_xliff/test_odf_xliff.py
|
||||
)
|
||||
|
||||
if ! has_version "dev-python/iniparse[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/convert/test_ini2po.py
|
||||
translate/convert/test_po2ini.py
|
||||
)
|
||||
fi
|
||||
|
||||
if ! has_version "media-video/gaupol[${PYTHON_USEDEP}]"; then
|
||||
EPYTEST_IGNORE+=(
|
||||
translate/storage/test_subtitles.py
|
||||
)
|
||||
fi
|
||||
|
||||
epytest
|
||||
}
|
||||
|
||||
python_install_all() {
|
||||
distutils-r1_python_install_all
|
||||
|
||||
insinto /usr
|
||||
doins -r translate/share
|
||||
|
||||
if ! use html; then
|
||||
rm "${ED}"/usr/bin/{html2po,po2html} || die
|
||||
fi
|
||||
if ! use ical; then
|
||||
rm "${ED}"/usr/bin/{ical2po,po2ical} || die
|
||||
fi
|
||||
if ! use ini; then
|
||||
rm "${ED}"/usr/bin/{ini2po,po2ini} || die
|
||||
fi
|
||||
if ! use subtitles; then
|
||||
rm "${ED}"/usr/bin/{sub2po,po2sub} || die
|
||||
fi
|
||||
}
|
||||
Reference in New Issue
Block a user