x11-misc/appmenu-gtk-module: add 25.04

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

x11-misc/appmenu-gtk-module/Manifest

@@ -1 +1,2 @@
 DIST appmenu-gtk-module-24.05.tar.xz 41364 BLAKE2B 45593cad5431f1b12fd7bc710399f7be7ff381d5757672c90db42187197de67b80f4436fc402e59abfa164d6d659557fb5a57737020d4cda361a2904154e9878 SHA512 0b233e56663f1e46f35b8edda5ea551f9569f6ffc20730fc62fcc090cf14a4032d58c7b8f03f14b29e9433f8ccd9fc89e3de7be50141fba5f85f5bf219517fa7
+DIST appmenu-gtk-module-25.04.tar.xz 41392 BLAKE2B 7dd85a8c27546fe9d752f6ce58146752fd34e415642ee2366cec324ccbc0f0f16b08d5c599b5d6885e3a42f6e680f59ea853f3f4d32051a2c838042ec71808b0 SHA512 18da544ee18a03d5d44334fb4ca21cba8e8305b3e89a12dbd5026d2c22827f7d0d361919159bbedb24e6396f7d2c738dd671025e9c74a699c7b6201c3a216e10

x11-misc/appmenu-gtk-module/appmenu-gtk-module-25.04.ebuild

@@ -0,0 +1,77 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit edo gnome2-utils flag-o-matic meson systemd virtualx
+
+DESCRIPTION="Application menu module for GTK"
+HOMEPAGE="https://gitlab.com/vala-panel-project/vala-panel-appmenu"
+SRC_URI="https://gitlab.com/-/project/6865053/uploads/4f517338d3c65a0ea6f49faf36a4f3e6/${P}.tar.xz"
+
+LICENSE="LGPL-3+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc64 ~riscv ~x86"
+IUSE="gtk2 test wayland"
+# Tests are manual and hang in the ebuild
+RESTRICT="!test? ( test ) test"
+
+RDEPEND="
+	dev-libs/glib[dbus]
+	>=x11-libs/gtk+-3.22.0:3[wayland?,X]
+	gtk2? ( >=x11-libs/gtk+-2.24.0:2 )
+"
+DEPEND="${RDEPEND}
+	wayland? ( dev-libs/wayland )
+"
+BDEPEND="virtual/pkgconfig"
+
+PATCHES=(
+	"${FILESDIR}/${PN}-0.7.6-no-automagic-gtk.patch"
+	"${FILESDIR}/${PN}-24.05-no-automagic-unitdir.patch"
+)
+
+src_configure() {
+	# defang automagic dependencies, bug #785619
+	use wayland || append-cflags -DGENTOO_GTK_HIDE_WAYLAND
+
+	# outputs [ '2', '3' ] OR [ '3' ]
+	local gtks="[$(usex gtk2 " '2'," '') '3' ]"
+
+	local emesonargs=(
+		-Dgtk="${gtks}"
+		-Duserunitdir="$(systemd_get_userunitdir)"
+		$(meson_use test tests)
+	)
+
+	meson_src_configure
+}
+
+my_test() {
+	cd "${BUILD_DIR}"/tests || die
+
+	local name
+	for name in hello radio tester ; do
+		edo ./${name}
+	done
+}
+
+src_test() {
+	virtx my_test
+}
+
+src_install() {
+	meson_src_install
+
+	mv "${ED}"/usr/share/doc/appmenu-gtk-module/* "${ED}"/usr/share/doc/${PF} || die
+	rmdir "${ED}"/usr/share/doc/appmenu-gtk-module || die
+
+	rm "${ED}"/usr/share/licenses/appmenu-gtk-module/LICENSE || die
+
+	exeinto /etc/X11/xinit/xinitrc.d
+	newexe "${FILESDIR}"/${PN}-r1 85-${PN}
+}
+
+pkg_postinst() {
+	gnome2_schemas_update
+}