millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

xfce-extra/xfce4-screenshooter: Bump to 1.11.3

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-11-06 06:15:58 +01:00
parent 704c54046e
commit 2ad56dfbba
No known key found for this signature in database
GPG Key ID: 639ADAE2329E240E
2 changed files with 80 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
xfce-extra/xfce4-screenshooter/Manifest
View File

@ -1,2 +1,3 @@
DIST xfce4-screenshooter-1.11.1.tar.bz2 721424 BLAKE2B 386e203b534993f93ffa6fc8c6d15dcbcefd79ca1c133a61ff157b406d96cef30da58bb6dcc069fd7e1d9911a256adaaa4fa01541ab07d61f683f1f603f73477 SHA512 aee31311faea2bb08d5e29722da190b0c7e2b37948a688a49212cd57cc4efc3f43b3c1588d9326f97eb174771412c60707cc88ae2ee0596546e9750a06112588
DIST xfce4-screenshooter-1.11.2.tar.xz 178440 BLAKE2B e5debb794d40c76fa00287c9829c7f3d05c1e03a36917e4622c4d83dd0d611bf20c96a15a62d1d95e3b82286e483a5c4e140d7ac98bb10520ad6998e46420175 SHA512 99744a996ce11b8477a850b99e6c376b10fd975635f7cbec2d910009ce9f30b4db8828cc97e9e579b72b75bc9b93a0c6a3b9ee50dcab0d0fff74059fa035fe4f
DIST xfce4-screenshooter-1.11.3.tar.xz 180120 BLAKE2B 5c4f3066ef50d67b04fcc0cee18fcfa411aa068d59796975224d1dbc66ccd5fef185d6f8915c99c26cfb02fe692630f6527d1c1fd4deadea0c400336e8ba5191 SHA512 1f2cf3d2631644f3f5fd847fea3622e4e35690d2265a2dfd6abd0b6f84f83995600c0e89925fe170b2e026922914f843c81e74d8c25752925e7e750af38132a0

79
xfce-extra/xfce4-screenshooter/xfce4-screenshooter-1.11.3.ebuild Normal file
View File

@ -0,0 +1,79 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson xdg-utils
DESCRIPTION="Xfce4 screenshooter application and panel plugin"
HOMEPAGE="
https://docs.xfce.org/apps/xfce4-screenshooter/start
https://gitlab.xfce.org/apps/xfce4-screenshooter/
"
SRC_URI="
https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.xz
"
LICENSE="GPL-2+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~loong ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
IUSE="X wayland"
REQUIRED_USE="|| ( X wayland )"
# TODO: remove exo when we dep on libxfce4ui >= 4.21.0
DEPEND="
>=dev-libs/glib-2.66.0
>=x11-libs/gtk+-3.24.0:3[X?,wayland?]
>=x11-libs/pango-1.44.0
>=xfce-base/exo-4.18.0:=
>=xfce-base/xfce4-panel-4.18.0:=
>=xfce-base/libxfce4util-4.18.0:=
>=xfce-base/libxfce4ui-4.18.0:=
>=xfce-base/xfconf-4.18.0:=
wayland? (
>=dev-libs/wayland-1.20
>=gui-libs/gtk-layer-shell-0.7.0
)
X? (
>=x11-libs/libX11-1.6.7
>=x11-libs/libXext-1.0.0
>=x11-libs/libXfixes-4.0.0
>=x11-libs/libXi-1.7.8
x11-libs/libXtst
)
"
RDEPEND="
${DEPEND}
"
DEPEND+="
wayland? (
>=dev-libs/wayland-protocols-1.37
)
"
BDEPEND="
dev-util/glib-utils
sys-apps/help2man
sys-devel/gettext
virtual/pkgconfig
wayland? (
>=dev-util/wayland-scanner-1.20
)
"
src_configure() {
local emesonargs=(
$(meson_feature X x11)
$(meson_feature wayland)
$(meson_feature X xfixes)
)
meson_src_configure
}
pkg_postinst() {
xdg_icon_cache_update
}
pkg_postrm() {
xdg_icon_cache_update
}