millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2026-01-07 00:05:47 +03:00
Code Packages Projects Releases Wiki Activity

dev-python/python-neutronclient: Bump to 11.3.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny
2024-07-04 06:58:40 +02:00
parent c3c2a07721
commit 3f5ae618b0
2 changed files with 79 additions and 0 deletions
Download Patch File Download Diff File Expand all files Collapse all files

1
dev-python/python-neutronclient/Manifest
View File

@@ -1 +1,2 @@
DIST python-neutronclient-11.3.0.tar.gz 211322 BLAKE2B 495e2f8db5d85cc92d1990239999c920341cc18e2d519da4e458eb8e50b803aa77d838dc06f2a248ead2ee156a763103c5376b786fa99d97a0c6dff5659374ba SHA512 4115326f2a40957f1db94ee4e65f7399019fa135774fa9ed5f2ffc6d20f65f326fedc724639decb730ce9de0a0e82239e1ffe6ec4df59382adb16d9c3cfb64d5
DIST python-neutronclient-11.3.1.tar.gz 211410 BLAKE2B db1bed173ca546529502dc2ce564e950c6908f4fa3dc81eb78bc59dfa4ba3e608a058c2b143db111afba153eef9e62f3a7f3bb588faed9d306e3bc960fc33e94 SHA512 76e17bf2f0bce6bad939029beb3a75b840675582fcef766f61ac139d29d7f0632dae3a7ee3aea596c60e3b86b9e5cf24c8070f75a03a9c8066b92437fcdd03be

78
dev-python/python-neutronclient/python-neutronclient-11.3.1.ebuild Normal file
View File

@@ -0,0 +1,78 @@
# Copyright 1999-2024 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
DISTUTILS_USE_PEP517=setuptools
PYPI_NO_NORMALIZE=1
PYTHON_COMPAT=( python3_{10..11} )
inherit distutils-r1 pypi
DESCRIPTION="A client for the OpenStack Quantum API"
HOMEPAGE="
https://opendev.org/openstack/python-neutronclient/
https://github.com/openstack/python-neutronclient/
https://pypi.org/project/python-neutronclient/
"
LICENSE="Apache-2.0"
SLOT="0"
KEYWORDS="~amd64 ~arm64 ~riscv ~x86"
RDEPEND="
>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
>=dev-python/cliff-3.4.0[${PYTHON_USEDEP}]
>=dev-python/debtcollector-1.2.0[${PYTHON_USEDEP}]
>=dev-python/iso8601-0.1.11[${PYTHON_USEDEP}]
>=dev-python/netaddr-0.7.18[${PYTHON_USEDEP}]
>=dev-python/openstacksdk-1.5.0[${PYTHON_USEDEP}]
>=dev-python/osc-lib-1.8.0[${PYTHON_USEDEP}]
>=dev-python/oslo-i18n-3.15.3[${PYTHON_USEDEP}]
>=dev-python/oslo-log-3.36.0[${PYTHON_USEDEP}]
>dev-python/oslo-serialization-2.19.1[${PYTHON_USEDEP}]
>=dev-python/oslo-utils-3.33.0[${PYTHON_USEDEP}]
>=dev-python/os-client-config-1.28.0[${PYTHON_USEDEP}]
>=dev-python/keystoneauth1-3.8.0[${PYTHON_USEDEP}]
>=dev-python/python-keystoneclient-3.8.0[${PYTHON_USEDEP}]
>=dev-python/requests-2.14.2[${PYTHON_USEDEP}]
"
BDEPEND="
>dev-python/pbr-2.1.0[${PYTHON_USEDEP}]
test? (
dev-python/bandit[${PYTHON_USEDEP}]
dev-python/fixtures[${PYTHON_USEDEP}]
dev-python/oslotest[${PYTHON_USEDEP}]
dev-python/python-openstackclient[${PYTHON_USEDEP}]
dev-python/subunit[${PYTHON_USEDEP}]
dev-python/requests-mock[${PYTHON_USEDEP}]
dev-python/testtools[${PYTHON_USEDEP}]
dev-python/testscenarios[${PYTHON_USEDEP}]
dev-python/tempest[${PYTHON_USEDEP}]
)
"
distutils_enable_tests unittest
src_prepare() {
# Needs osprofile
rm neutronclient/tests/unit/test_http.py || die
distutils-r1_src_prepare
}
python_test() {
# functional tests require cloud instance access
eunittest -b neutronclient.tests.unit
}
python_install() {
distutils-r1_python_install
# stupid stupid stupid
local SITEDIR="${D}$(python_get_sitedir)" || die
cd "${SITEDIR}" || die
local egg=( python_neutronclient*.dist-info )
[[ -d ${egg[0]} ]] || die "python_quantumclient*.dist-info not found"
ln -s "${egg[0]}" "${egg[0]/neutron/quantum}" || die
ln -s neutronclient quantumclient || die
ln -s neutron quantumclient/quantum || die
}