dev-util/trace-cmd: drop 3.3

Signed-off-by: Yixun Lan <dlan@gentoo.org>

dev-util/trace-cmd/Manifest

@@ -1,3 +1,2 @@
 DIST trace-cmd-v3.3.2.tar.gz 366804 BLAKE2B 506fcff2e7fccea76632f63545e12871819d88adc9e782b34c793b2c5eb185a5546b0bdc4fba8245dd8c57c945d1377c601720ef3f34cb261d27a6875df899df SHA512 139b4a00248479c88e2267c5e8ab368a4fb94687c47fe5192ccceb2d0919689072458fcbae2c9ccd27f538a67b1a373bdb539345938e39f23eec80fe5285da35
 DIST trace-cmd-v3.3.3.tar.gz 366872 BLAKE2B b07848ca789092fda3aeadbf47d65a9f84c53af927c4c43d9f00c777460085795efebdf973a9708ef35dca0f20e773e5e39a5f4ef25f7297ad9bce449d2953b8 SHA512 df3604e3f897449b7685faddb7c61c6bcce2dbe26c504200710f73d4e24047b34b3df819855d6ac52934c8515725d1b25bd0089c66de700dac0990f44d0069a6
-DIST trace-cmd-v3.3.tar.gz 363405 BLAKE2B bc77ced96d47fe8284ad2252b7f6e51ae73b248a41908f255db68277ffccb35b34ede9a5e85f5f284b701c40b009f2d0ca091fb7db554793ae1470d6585e07ed SHA512 0857bea0bceb196bdb44164eefb8a05384c640f5a4d569dcbf26d80302b21bf17880eaba07c3da81c8812abe0f451219c26ba02b7bf9103eb1d0e88f1da84703

dev-util/trace-cmd/trace-cmd-3.3.ebuild

@@ -1,98 +0,0 @@
-# Copyright 1999-2025 Gentoo Authors
-# Distributed under the terms of the GNU General Public License v2
-
-EAPI=8
-
-DISTUTILS_OPTIONAL=1
-PYTHON_COMPAT=( python3_{11..12} )
-
-inherit linux-info meson python-single-r1
-
-DESCRIPTION="User-space front-end for Ftrace"
-HOMEPAGE="https://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git"
-
-if [[ ${PV} == *9999 ]] ; then
-	EGIT_REPO_URI="https://git.kernel.org/pub/scm/utils/trace-cmd/${PN}.git"
-	inherit git-r3
-else
-	SRC_URI="https://git.kernel.org/pub/scm/utils/trace-cmd/trace-cmd.git/snapshot/${PN}-v${PV}.tar.gz"
-	KEYWORDS="amd64 ~arm64 ~riscv ~x86"
-	S="${WORKDIR}/${PN}-v${PV}"
-fi
-
-LICENSE="GPL-2+ LGPL-2.1+"
-SLOT="0/${PV}"
-IUSE="python test"
-REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
-# Tests segfault for now?
-RESTRICT="!test? ( test ) test"
-
-RDEPEND="
-	>=app-arch/zstd-1.4
-	>=dev-libs/libtracefs-1.8
-	>=dev-libs/libtraceevent-1.6.3
-	virtual/zlib:=
-	sys-process/audit
-	python? ( ${PYTHON_DEPS} )
-"
-DEPEND="
-	${RDEPEND}
-	sys-kernel/linux-headers
-	test? ( dev-util/cunit )
-"
-BDEPEND="
-	app-text/asciidoc
-	virtual/pkgconfig
-	python? ( dev-lang/swig )
-"
-
-pkg_setup() {
-	local CONFIG_CHECK="
-		~TRACING
-		~FTRACE
-		~BLK_DEV_IO_TRACE"
-
-	linux-info_pkg_setup
-
-	# TODO: Once we have options for doc+tests, we can revisit Python being
-	# single-impl.
-	use python && python-single-r1_pkg_setup
-}
-
-src_prepare() {
-	default
-
-	# Due to the in-progress meson build transaction, we decide to separate
-	# the libtracecmd as an independent package, see bug #909439
-	# Note: dev-util/trace-cmd still use in-source static libtracecmd duo to
-	# it still use internal private API.
-	sed -i -e "/^libtracecmd_standalone_build/s/true/false/" \
-		"${S}"/lib/meson.build || die
-}
-
-src_configure() {
-	local emesonargs=(
-		-Dasciidoctor=false
-		$(meson_use python)
-	)
-
-	# TODO: udis86 isn't wired up to meson at all
-	# TODO: get docs & tests optional upstream
-	# TODO: audit/zstd/zlib lack meson options for now. Previously, the situation
-	# was somewhat automagic, so this isn't a huge loss for now, but we should
-	# upstream some build options for these.
-	meson_src_configure
-}
-
-src_install() {
-	meson_src_install
-	use python && python_install
-
-	# TODO: fix bash completion name
-	mv "${D}"/usr/share/bash-completion/completions/${PN}.bash \
-		"${D}"/usr/share/bash-completion/completions/${PN} || die
-}
-
-python_install() {
-	python_optimize "${D}$(python_get_sitedir)"
-}