dev-libs/libinput: Version bump to 1.29.2

Signed-off-by: Matt Turner <mattst88@gentoo.org>

dev-libs/libinput/Manifest

@@ -1,2 +1,3 @@
 DIST libinput-1.28.1.tar.bz2 864820 BLAKE2B fe245274951e8a010abfcd72722f8b5f96f9d879535374ee5180da56c575ca511c2007058a584d2b2336941f4242125876132a3bf398ccf2c855fb7a6ea69865 SHA512 354a91f2239da5e5bbb12bb7473bd1fb7adf69e6243e8da786ace9e80eda6c8f733620b5f1e20411c732fcfa4dedf5ccd2e722a78693e564a24771e80f1c72aa
 DIST libinput-1.29.1.tar.bz2 895235 BLAKE2B 7983c2c9020b6f4e4c3c78ac6808f84be541547af4b3d2b671902b53e2a516bd5ae2042fc7b9b1b00d0df27f1863292b8012cea26a5723fc5935b658f9be737d SHA512 9e5f352c2279c1234fe952ae6ecd0a275a48a595cbea8e26de682ab278499cf31a36d720800b02fd0472b20e5479ae9880633e03b1240e63d50bb6e8a1d2baf2
+DIST libinput-1.29.2.tar.bz2 896277 BLAKE2B 9a5c479a9c636862cab138c72529e470cbd67ba6df37cfe75f3256470dcee5c3c972c957697dd37e5d7b9c35112a84d63bad42ddfe2b872cd119e4deeb4b918a SHA512 fe57f4179f830844506fcf50231d43545dce9099617957abf771cca7b263aa8d65997dc8ade39d00bc865c851deb0468ba330d3be38754fb23923304dba3ae8f

dev-libs/libinput/libinput-1.29.2.ebuild

@@ -0,0 +1,102 @@
+# Copyright 2014-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+PYTHON_COMPAT=( python3_{11..14} )
+inherit meson optfeature python-any-r1 udev
+
+DESCRIPTION="Library to handle input devices in Wayland"
+HOMEPAGE="https://www.freedesktop.org/wiki/Software/libinput/ https://gitlab.freedesktop.org/libinput/libinput"
+SRC_URI="https://gitlab.freedesktop.org/${PN}/${PN}/-/archive/${PV}/${P}.tar.bz2"
+
+LICENSE="MIT"
+SLOT="0/10"
+if [[ $(ver_cut 3) -lt 900 ]] ; then
+	KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~loong ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86"
+fi
+IUSE="doc input_devices_wacom test"
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	input_devices_wacom? ( >=dev-libs/libwacom-2.15:= )
+	>=dev-libs/libevdev-1.9.902
+	>=sys-libs/mtdev-1.1
+	virtual/libudev:=
+	virtual/udev
+"
+DEPEND="
+	${RDEPEND}
+	test? ( >=dev-libs/check-0.9.10 )
+"
+BDEPEND="
+	virtual/pkgconfig
+	doc? (
+		$(python_gen_any_dep '
+			dev-python/commonmark[${PYTHON_USEDEP}]
+			dev-python/recommonmark[${PYTHON_USEDEP}]
+			dev-python/sphinx[${PYTHON_USEDEP}]
+			>=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]
+		')
+		>=app-text/doxygen-1.8.3
+		>=media-gfx/graphviz-2.38.0
+	)
+	test? (
+		$(python_gen_any_dep '
+			dev-python/pytest[${PYTHON_USEDEP}]
+			dev-python/pytest-xdist[${PYTHON_USEDEP}]
+		')
+	)
+"
+#	test? ( dev-debug/valgrind )
+
+python_check_deps() {
+	if use doc; then
+		python_has_version \
+			"dev-python/commonmark[${PYTHON_USEDEP}]" \
+			"dev-python/recommonmark[${PYTHON_USEDEP}]" \
+			"dev-python/sphinx[${PYTHON_USEDEP}]" \
+			">=dev-python/sphinx-rtd-theme-0.2.4[${PYTHON_USEDEP}]" \
+		|| return
+	fi
+	if use test; then
+		python_has_version \
+			"dev-python/pytest[${PYTHON_USEDEP}]" \
+			"dev-python/pytest-xdist[${PYTHON_USEDEP}]" \
+		|| return
+	fi
+}
+
+src_prepare() {
+	default
+	sed "s@, '-Werror'@@" -i meson.build || die #744250
+}
+
+src_configure() {
+	# gui can be built but will not be installed
+	local emesonargs=(
+		-Ddebug-gui=false
+		$(meson_use doc documentation)
+		$(meson_use input_devices_wacom libwacom)
+		$(meson_use test tests)
+		-Dudev-dir="${EPREFIX}$(get_udevdir)"
+	)
+	meson_src_configure
+}
+
+src_install() {
+	meson_src_install
+	if use doc ; then
+		docinto html
+		dodoc -r "${BUILD_DIR}"/Documentation/.
+	fi
+}
+
+pkg_postinst() {
+	optfeature "measure and replay tools" dev-python/libevdev
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}