dev-python/pyqt6-webengine: add 6.10.0

Signed-off-by: Ionen Wolkens <ionen@gentoo.org>

dev-python/pyqt6-webengine/Manifest

@@ -1 +1,2 @@
+DIST pyqt6_webengine-6.10.0.tar.gz 37053 BLAKE2B b87f4f12de50fe124a310ae2a121f908f8e70a3c6bc70011368a9b79934614f46d2d7441448ec1971827cae6f0942ab7adcd360f6e191fa0b2793140a6baa871 SHA512 d331203281be2a5d176abe3dca8868a021acbc66e37e73952c6f706a7131d56d2caf66453b048720d4cc217f9db0d731cf49890048bcef3f207f25a8595f64aa
 DIST pyqt6_webengine-6.9.0.tar.gz 34616 BLAKE2B ce6143b16e60ad133c827996f03b310008b025f616739d4c7949dc8916513dfd24bcb44d269465a1bffe1a608728f77d381a15363d3761815d54622ab7490a33 SHA512 3e84439fa7f2ab1c231eac556545968d37e7bef30779d09376eedb5861ab47f9a83e72c8834fbfa4aef27a61e4ff2d797615e3f80362bcd1613954d27af8c6a8

dev-python/pyqt6-webengine/pyqt6-webengine-6.10.0.ebuild

@@ -0,0 +1,67 @@
+# Copyright 2022-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_EXT=1
+DISTUTILS_USE_PEP517=sip
+PYTHON_COMPAT=( python3_{11..14} )
+inherit distutils-r1 flag-o-matic multiprocessing pypi qmake-utils
+
+QT_PV=$(ver_cut 1-2):6
+
+DESCRIPTION="Python bindings for QtWebEngine"
+HOMEPAGE="https://www.riverbankcomputing.com/software/pyqtwebengine/"
+
+LICENSE="GPL-3"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+IUSE="debug quick +widgets"
+
+RDEPEND="
+	>=dev-python/pyqt6-${QT_PV%:*}[gui,ssl,webchannel,${PYTHON_USEDEP}]
+	>=dev-qt/qtbase-${QT_PV}[gui,widgets?]
+	>=dev-qt/qtwebengine-${QT_PV}[widgets]
+	quick? (
+		dev-python/pyqt6[qml]
+		>=dev-qt/qtwebengine-${QT_PV}[qml]
+	)
+	widgets? ( dev-python/pyqt6[network,printsupport,widgets] )
+"
+DEPEND="${RDEPEND}"
+BDEPEND="
+	>=dev-python/pyqt-builder-1.19[${PYTHON_USEDEP}]
+	>=dev-python/sip-6.13.1[${PYTHON_USEDEP}]
+	>=dev-qt/qtbase-${QT_PV}
+"
+
+src_prepare() {
+	default
+
+	# hack: PyQt-builder runs qmake without our arguments and calls g++
+	# or clang++ depending on what qtbase was built with, not used for
+	# building but fails with -native-symlinks
+	mkdir "${T}"/cxx || die
+	local cxx
+	! cxx=$(type -P "${CHOST}"-g++) || ln -s -- "${cxx}" "${T}"/cxx/g++ || die
+	! cxx=$(type -P "${CHOST}"-clang++) || ln -s -- "${cxx}" "${T}"/cxx/clang++ || die
+	PATH=${T}/cxx:${PATH}
+}
+
+python_configure_all() {
+	append-cxxflags -std=c++17 # for old gcc / clang that use <17 (bug #892331)
+	append-cxxflags ${CPPFLAGS} # respect CPPFLAGS notably for DISTUTILS_EXT=1
+
+	DISTUTILS_ARGS=(
+		--jobs="$(makeopts_jobs)"
+		--qmake="$(qt6_get_bindir)"/qmake
+		--qmake-setting="$(qt6_get_qmake_args)"
+		--verbose
+
+		--enable=QtWebEngineCore
+		$(usex quick --{enable,disable}=QtWebEngineQuick)
+		$(usex widgets --{enable,disable}=QtWebEngineWidgets)
+
+		$(usev debug '--debug --qml-debug --tracing')
+	)
+}

profiles/package.mask

@@ -108,6 +108,7 @@ net-libs/NativeThread
 # A common issue with 6.10 is builds failing to find Qt private headers
 # as it (now) requires searching for e.g. GuiPrivate in CMakeLists.txt.
 =dev-python/pyqt6-6.10*
+=dev-python/pyqt6-webengine-6.10*
 =dev-python/pyside-6.10.0*
 =dev-qt/qt-docs-6.10.0*
 =dev-qt/qt3d-6.10.0*