xfce-base/libxfce4ui: Bump to 4.21.3

Signed-off-by: Michał Górny <mgorny@gentoo.org>

xfce-base/libxfce4ui/Manifest

@@ -1,2 +1,3 @@
 DIST libxfce4ui-4.20.2.tar.bz2 1223663 BLAKE2B 0105ec24cb2b77a38d319d11d242af15f2b67b14836402607f1fa691cd35c75d863be0dcd70c991bcda8098a0e9694df9bf5f7327189c39fe6fd4f564c272648 SHA512 cc82e862de0b5ce7dc5b43b84a6231de131ad76a810c3e66e771ae364fdb4b1a91be2111ab8d601d97fffd692253e8bebf496867cef743f9344a4977fb8ff8d2
 DIST libxfce4ui-4.21.2.tar.xz 515320 BLAKE2B 380a9c568f0884506d77f0fa4c3a9e0c03e43191d8e2bd5b8e7d12bab74fc88e364d2e2f5a9413844ae8f0be627371a0c9fb23e4b861a3dd6c25e9e0eabaa7a7 SHA512 624974fdfc57d6941b0e15f0a4c6ce153fdc3260bd60c05bc436dd9d9428930f9eccb1ce6d1748af89b73769c7c91ae8f8a5c77713c5db17d03a2da66afc4db8
+DIST libxfce4ui-4.21.3.tar.xz 520328 BLAKE2B 93cafe91100ce736719472fe65c7fb3240b79d7759292258d19451c651bf715f5f77ebff5392f40f11327f98ff032bf5733399937603f8f18ae85944f89a2e35 SHA512 68af18fce4879fd5de1b2a59b03d979809eccda5fad77fbd41709d24fb714d0a730612e9766d17bfe87b461480219529b21e4fb986a61c829fd8b38c5c7643ac

xfce-base/libxfce4ui/libxfce4ui-4.21.3.ebuild

@@ -0,0 +1,85 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit meson xdg-utils vala
+
+DESCRIPTION="Unified widget and session management libs for Xfce"
+HOMEPAGE="
+	https://docs.xfce.org/xfce/libxfce4ui/start
+	https://gitlab.xfce.org/xfce/libxfce4ui/
+"
+SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.xz"
+
+LICENSE="LGPL-2+ GPL-2+"
+SLOT="0"
+KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86 ~amd64-linux ~x86-linux"
+IUSE="glade gtk-doc +introspection startup-notification system-info vala wayland X"
+REQUIRED_USE="
+	|| ( wayland X )
+	vala? ( introspection )
+"
+
+DEPEND="
+	>=dev-libs/glib-2.72.0
+	>=x11-libs/gdk-pixbuf-2.42.8
+	>=x11-libs/gtk+-3.24.0:3[introspection?,wayland?,X?]
+	>=xfce-base/libxfce4util-4.17.2:=[introspection?,vala?]
+	>=xfce-base/xfconf-4.12.0:=
+	glade? ( >=dev-util/glade-3.5.0:3.10 )
+	introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2 )
+	system-info? (
+		>=dev-libs/libgudev-232
+		>=gnome-base/libgtop-2.24.0
+		>=media-libs/libepoxy-1.2
+	)
+	X? (
+		>=x11-libs/libICE-1.0.10
+		>=x11-libs/libSM-1.2.3
+		>=x11-libs/libX11-1.6.7
+		startup-notification? ( >=x11-libs/startup-notification-0.4 )
+	)
+"
+RDEPEND="
+	${DEPEND}
+"
+DEPEND+="
+	x11-base/xorg-proto
+"
+BDEPEND="
+	dev-build/xfce4-dev-tools
+	dev-util/glib-utils
+	>=sys-devel/gettext-0.19.8
+	virtual/pkgconfig
+	gtk-doc? ( dev-util/gtk-doc )
+	vala? ( $(vala_depend) )
+"
+
+src_configure() {
+	local emesonargs=(
+		$(meson_use gtk-doc)
+		$(meson_use introspection)
+		$(meson_feature vala)
+		$(meson_feature X x11)
+		$(meson_feature wayland)
+		$(meson_feature X session-management)
+		$(meson_feature startup-notification)
+		$(meson_feature system-info libgtop)
+		$(meson_feature system-info epoxy)
+		$(meson_feature system-info gudev)
+		$(meson_feature glade)
+		-Dvendor-info=Gentoo
+	)
+
+	use vala && vala_setup
+	meson_src_configure
+}
+
+pkg_postinst() {
+	xdg_icon_cache_update
+}
+
+pkg_postrm() {
+	xdg_icon_cache_update
+}