dev-python/hishel: Bump to 1.1.6

Signed-off-by: Michał Górny <mgorny@gentoo.org>

dev-python/hishel/Manifest

@@ -1,3 +1,4 @@
 DIST hishel-0.1.5.gh.tar.gz 1065622 BLAKE2B 926801f579a57cc2b45cb6cd5326459493452d34b32a2725b906307dcc4575b1297b35ffc626e51acc5805216731552d58c672dedb0541f2c771f153daee960d SHA512 b1f850895b147da616ace381d98ac9b6a15386d7e79d64a57a4e87f9bd0b42009a6ffa15fe1f8e46c57f8bc664c3af97d46e5adb81211e30fae87dab898f7734
 DIST hishel-1.1.4.gh.tar.gz 1097778 BLAKE2B 0e2569a0e3c956d3df498f8b3ce5da267a584b0c452541ebeb7d43cc8433ab9d929594ff2487394effeac00dec27bc2c8be48ef4e6cb64cfaf28bc5c0b2d6e4e SHA512 ff52c048edaef0fa50f2c38371e33128ec8f1ae1682d78de49c1a48ee7cec82cc21ba9e4ef82cb349fd6e95c032d60cea5ce4b01cc8dcb6e0e4ecfd08fb4bfdc
 DIST hishel-1.1.5.gh.tar.gz 1098331 BLAKE2B 5b3b9fc3770842bc1323c0ca46718d9ce82265dc11321f3f9335aa69fa1f6a78384125139a249af3b268d9035d213b4dc3f09532b0a06158c1986746285a2757 SHA512 47de167f3e24a7db05cbcb1b8d549b0abf9fe4d39829a0a41ab7f86f71697ac4ea78c32ad3901d5edca5e520fd1862e47ab79dd0ce635abe37224ff0ad37869e
+DIST hishel-1.1.6.gh.tar.gz 1098160 BLAKE2B a02509ba9516e9b1125c6f40d2eeadcc79932586ff60d709050eb6123422fb77584dd7aa8749c4efa9f434323d1e3d916bbc80cbddcd089628ce5ceaf2e70272 SHA512 56c330ccc47f5eced158b00a972508a5f9c14ec09c8263297e12c57de9f105ea200807988f36607d2b21500eeb7d0389069e55c77f258d62550ed1ed6af8aa11

dev-python/hishel/hishel-1.1.6.ebuild

@@ -0,0 +1,73 @@
+# Copyright 2024-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+DISTUTILS_USE_PEP517=hatchling
+PYTHON_COMPAT=( python3_{11..14} )
+
+inherit distutils-r1
+
+DESCRIPTION="An elegant HTTP Cache implementation for HTTPX and HTTP Core"
+HOMEPAGE="
+	https://github.com/karpetrosyan/hishel/
+	https://pypi.org/project/hishel/
+"
+SRC_URI="
+	https://github.com/karpetrosyan/${PN}/archive/refs/tags/${PV}.tar.gz
+		-> ${P}.gh.tar.gz
+"
+
+LICENSE="BSD"
+SLOT="0"
+KEYWORDS="~amd64 ~arm64"
+
+RDEPEND="
+	>=dev-python/anyio-4.9.0[${PYTHON_USEDEP}]
+	>=dev-python/anysqlite-0.0.5[${PYTHON_USEDEP}]
+	>=dev-python/httpx-0.28.1[${PYTHON_USEDEP}]
+	>=dev-python/msgpack-1.1.2[${PYTHON_USEDEP}]
+	>=dev-python/typing-extensions-1.14.1[${PYTHON_USEDEP}]
+"
+
+BDEPEND="
+	${RDEPEND}
+	dev-python/hatch-fancy-pypi-readme[${PYTHON_USEDEP}]
+	test? (
+		dev-db/redis
+		>=dev-python/boto3-1.15.3[${PYTHON_USEDEP}]
+		>=dev-python/inline-snapshot-0.28.0[${PYTHON_USEDEP}]
+		>=dev-python/redis-6.2.0[${PYTHON_USEDEP}]
+		>=dev-python/time-machine-2.19.0[${PYTHON_USEDEP}]
+		>=dev-python/trio-0.30.0[${PYTHON_USEDEP}]
+	)
+"
+
+EPYTEST_PLUGINS=( anyio )
+distutils_enable_tests pytest
+
+src_test() {
+	local EPYTEST_DESELECT=(
+		# Internet
+		tests/test_async_httpx.py
+		tests/test_requests.py
+		tests/test_sync_httpx.py
+	)
+
+	local redis_pid="${T}"/redis.pid
+	local redis_port=6379
+
+	einfo "Starting Redis"
+	"${EPREFIX}"/usr/sbin/redis-server - <<- EOF
+		daemonize yes
+		pidfile ${redis_pid}
+		port ${redis_port}
+		bind 127.0.0.1 ::1
+	EOF
+
+	# Run the tests
+	distutils-r1_src_test
+
+	# Clean up afterwards
+	kill "$(<"${redis_pid}")" || die
+}