millerson.name/gentoo
2
0
Fork 0
mirror of https://github.com/gentoo-mirror/gentoo.git synced 2025-12-08 00:05:33 +03:00
Code Issues Packages Projects Releases Wiki Activity

xfce-base/xfce4-panel: Bump to 4.21.1

Browse Source 
Signed-off-by: Michał Górny <mgorny@gentoo.org>
This commit is contained in:
Michał Górny 2025-11-16 17:32:48 +01:00
parent bf3a715099
commit 5f1c4d6042
No known key found for this signature in database
GPG Key ID: 8E32347AF4055AE8
2 changed files with 83 additions and 0 deletions
Show Stats Download Patch File Download Diff File Expand all files Collapse all files

1
xfce-base/xfce4-panel/Manifest
View File

@ -1,2 +1,3 @@
DIST xfce4-panel-4.20.5.tar.bz2 2293754 BLAKE2B 29983f16c75070640613d733524243df85e81c5ac53721d704ae4380004e95e9d80a909e802b1e1d16c462645364839105205ced07bf3a05cf1467ba0a42dc19 SHA512 bde9d94a463b526bf41cf0f6568c70f899f03da8dbe5c654f9857e2bcc5ac1d25681f47c185ab3a0b4af4516703b0e30c55ff9a26a8ba52a36db24955e705327
DIST xfce4-panel-4.21.0.tar.xz 834780 BLAKE2B cf06cd31589e3f2ce854df7677e6ae54e59432f69cb552a1bd4069798d61a287b0e476e355a3f65c5862134b8a1b1b231fe5660fa7a1e306ca912da5796b4d5e SHA512 64e848af99eb6d11676819ee96b97bf49db7054d12d688177e0f21d9af74cecf3d14a102c01198a2e901568e848149d2c8e9bdb5489a5ddddb8150a78c6f53a6
DIST xfce4-panel-4.21.1.tar.xz 827800 BLAKE2B 32e36deb87b64ff2f2eb415a237db5bc8f7a64ea8069218920adcb1f7d62ac9e8269e8a603a231bd327587398f3ad9ccfd4dfeb9a2ee63cc63f52ef595012b79 SHA512 ce662bf001d8984f3162e906429d4a804b2d739ccaa7a1f6187698ff8cea8cea1d7f2e7a8d4038d347fcb0951cac5fa7ddf5486d779b7eacf37e1941ae6c160c

82
xfce-base/xfce4-panel/xfce4-panel-4.21.1.ebuild Normal file
View File

@ -0,0 +1,82 @@
# Copyright 1999-2025 Gentoo Authors
# Distributed under the terms of the GNU General Public License v2
EAPI=8
inherit meson vala xdg-utils
DESCRIPTION="Panel for the Xfce desktop environment"
HOMEPAGE="
https://docs.xfce.org/xfce/xfce4-panel/start
https://gitlab.xfce.org/xfce/xfce4-panel/
"
SRC_URI="https://archive.xfce.org/src/xfce/${PN}/${PV%.*}/${P}.tar.xz"
LICENSE="GPL-2+ LGPL-2.1+"
SLOT="0"
KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~loong ~mips ~ppc ~ppc64 ~riscv ~sparc ~x86"
IUSE="+dbusmenu gtk-doc introspection vala wayland X"
REQUIRED_USE="
|| ( wayland X )
vala? ( introspection )
"
DEPEND="
>=dev-libs/glib-2.74.0
>=x11-libs/cairo-1.16.0
>=x11-libs/gtk+-3.24.0:3[X?,introspection?,wayland?]
>=xfce-base/exo-4.18.0:=
>=xfce-base/garcon-4.18.0:=
>=xfce-base/libxfce4ui-4.21.3:=
>=xfce-base/libxfce4util-4.18.0:=[introspection?,vala?]
>=xfce-base/libxfce4windowing-4.20.1:=[X?]
>=xfce-base/xfconf-4.18.0:=
dbusmenu? ( >=dev-libs/libdbusmenu-16.04.0[gtk3] )
introspection? ( >=dev-libs/gobject-introspection-1.82.0-r2:= )
wayland? (
>=dev-libs/wayland-1.20
>=gui-libs/gtk-layer-shell-0.7.0
)
X? (
>=x11-libs/libX11-1.6.7
>=x11-libs/libXext-1.0.0
x11-libs/libwnck:3
)
"
RDEPEND="
${DEPEND}
"
BDEPEND="
gtk-doc? ( dev-util/gtk-doc )
vala? ( $(vala_depend) )
dev-build/xfce4-dev-tools
dev-util/gdbus-codegen
dev-util/intltool
sys-devel/gettext
virtual/pkgconfig
"
src_configure() {
local emesonargs=(
$(meson_use gtk-doc)
$(meson_use introspection)
$(meson_feature vala)
$(meson_feature X x11)
$(meson_feature wayland)
$(meson_feature wayland gtk-layer-shell)
$(meson_feature dbusmenu)
)
use vala && vala_setup
meson_src_configure
}
pkg_postinst() {
xdg_icon_cache_update
xdg_desktop_database_update
}
pkg_postrm() {
xdg_icon_cache_update
xdg_desktop_database_update
}