sci-libs/indilib: add 2.1.7

Signed-off-by: Andreas Sturmlechner <asturm@gentoo.org>

sci-libs/indilib/Manifest

@@ -1 +1,2 @@
 DIST indilib-2.1.6a.tar.gz 4474992 BLAKE2B a506714cac835ec421a354ae65f892169d23ff216b4fd9a7647624d50d2f2687e766f732be3341a7e689c1e40480a446bcf982b8890cbd664c3b756b78faf63e SHA512 c99ad1709b6bd99ea05f4d1171843f5526a59a034eebdf6ac8590df785f7bae8b19655232db10485f1064b3db65982f06df21fd67452ce586fbed2b7182e24c6
+DIST indilib-2.1.7.tar.gz 3265446 BLAKE2B 6feadae6f0f142ce786c77b6dea10f443a31927c9de0759f7ee1ae81eea6ef296456f16413f5ff49ec61dbf296418a34773191d66875a5f47eb89d2659937a3f SHA512 54ab9bd632befa19a8af04e572808fccc782ec84ce7962940347a3bf49f761ba13af06ced7152828619e0dff2c63f6c19944fe873ead18b6f38c92b11d5ca3e6

sci-libs/indilib/indilib-2.1.7.ebuild

@@ -0,0 +1,80 @@
+# Copyright 1999-2025 Gentoo Authors
+# Distributed under the terms of the GNU General Public License v2
+
+EAPI=8
+
+inherit cmake udev
+
+DESCRIPTION="INDI Astronomical Control Protocol library"
+HOMEPAGE="https://www.indilib.org/"
+SRC_URI="https://github.com/${PN}/${PN/lib/}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
+S="${WORKDIR}/${P/lib/}"
+
+LICENSE="BSD GPL-2+ LGPL-2+ LGPL-2.1+"
+SLOT="0/1"
+KEYWORDS="~amd64 ~ppc ~ppc64 ~riscv ~x86"
+IUSE="ogg rtlsdr test"
+
+RESTRICT="!test? ( test )"
+
+RDEPEND="
+	dev-cpp/cpp-httplib:=
+	dev-cpp/nlohmann_json
+	dev-libs/hidapi
+	dev-libs/libev
+	media-libs/libjpeg-turbo:=
+	net-misc/curl
+	sci-libs/cfitsio:=
+	sci-libs/fftw:3.0=
+	sci-libs/gsl:=
+	sci-libs/libnova:=
+	virtual/zlib:=
+	virtual/libusb:1
+	ogg? (
+		media-libs/libogg
+		media-libs/libtheora:=
+	)
+	rtlsdr? ( net-wireless/rtl-sdr:= )
+"
+DEPEND="${RDEPEND}
+	kernel_linux? ( sys-kernel/linux-headers )
+	test? ( >=dev-cpp/gtest-1.8.0 )
+"
+
+src_configure() {
+	local mycmakeargs=(
+		-DINDI_SYSTEM_HIDAPILIB=ON
+		-DINDI_SYSTEM_HTTPLIB=ON
+		-DINDI_SYSTEM_JSONLIB=ON
+		-DINDI_BUILD_QT_CLIENT=OFF
+		-DINDI_BUILD_SHARED=ON
+		-DINDI_BUILD_STATIC=OFF
+		-DINDI_BUILD_XISF=OFF # not packaged
+		-DUDEVRULES_INSTALL_DIR="${EPREFIX}$(get_udevdir)"/rules.d
+		-DINDI_BUILD_EXAMPLES=OFF # nothing is installed
+		$(cmake_use_find_package ogg OggTheora)
+		$(cmake_use_find_package rtlsdr RTLSDR)
+		-DINDI_BUILD_UNITTESTS=$(usex test)
+		-DINDI_BUILD_INTEGTESTS=$(usex test)
+	)
+
+	cmake_src_configure
+}
+
+src_test() {
+	# Unit tests
+	BUILD_DIR="${BUILD_DIR}"/test cmake_src_test
+
+	# Integration tests
+	# They fail in parallel because they try to bind to the same port more
+	# than once.
+	BUILD_DIR="${BUILD_DIR}"/integs cmake_src_test -j1
+}
+
+pkg_postinst() {
+	udev_reload
+}
+
+pkg_postrm() {
+	udev_reload
+}